coding style: doc: remove empty lines at end of text files
[openocd.git] / configure.ac
1 AC_PREREQ(2.64)
2 AC_INIT([openocd], [0.10.0+dev],
3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
4 AC_CONFIG_SRCDIR([src/openocd.c])
5
6 m4_include([config_subdir.m4])dnl
7
8 # check for makeinfo before calling AM_INIT_AUTOMAKE
9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
10 AS_IF([test "x$MAKEINFO" = "x"], [
11   MAKEINFO='echo makeinfo missing; true'
12   AC_MSG_WARN([Info documentation will not be built.])
13 ])
14 AC_SUBST([MAKEINFO])
15
16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
17
18 AC_CONFIG_HEADERS([config.h])
19 AH_BOTTOM([
20 #include <helper/system.h>
21 #include <helper/types.h>
22 #include <helper/replacements.h>
23 ])
24
25 AC_LANG_C
26 AC_PROG_CC
27 AC_PROG_CC_C99
28 AM_PROG_CC_C_O
29 AC_PROG_RANLIB
30 PKG_PROG_PKG_CONFIG([0.23])
31
32 dnl disable checks for C++, Fortran and GNU Java Compiler
33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
36 AC_DISABLE_SHARED
37 AC_PROG_LIBTOOL
38 AC_SUBST([LIBTOOL_DEPS])
39
40 dnl configure checks required for Jim files (these are obsolete w/ C99)
41 AC_C_CONST
42 AC_TYPE_LONG_LONG_INT
43
44 AC_SEARCH_LIBS([ioperm], [ioperm])
45 AC_SEARCH_LIBS([dlopen], [dl])
46
47 AC_CHECK_HEADERS([sys/socket.h])
48 AC_CHECK_HEADERS([elf.h])
49 AC_CHECK_HEADERS([dirent.h])
50 AC_CHECK_HEADERS([fcntl.h])
51 AC_CHECK_HEADERS([malloc.h])
52 AC_CHECK_HEADERS([netdb.h])
53 AC_CHECK_HEADERS([poll.h])
54 AC_CHECK_HEADERS([pthread.h])
55 AC_CHECK_HEADERS([strings.h])
56 AC_CHECK_HEADERS([sys/ioctl.h])
57 AC_CHECK_HEADERS([sys/param.h])
58 AC_CHECK_HEADERS([sys/select.h])
59 AC_CHECK_HEADERS([sys/stat.h])
60 AC_CHECK_HEADERS([sys/sysctl.h])
61 AC_CHECK_HEADERS([sys/time.h])
62 AC_CHECK_HEADERS([sys/types.h])
63 AC_CHECK_HEADERS([unistd.h])
64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
65 #include <stdio.h>
66 #ifdef STDC_HEADERS
67 # include <stdlib.h>
68 # include <stddef.h>
69 #else
70 # ifdef HAVE_STDLIB_H
71 #  include <stdlib.h>
72 # endif
73 #endif
74 #ifdef HAVE_SYS_SOCKET_H
75 # include <sys/socket.h>
76 #endif
77 ])
78
79 AC_HEADER_ASSERT
80 AC_HEADER_STDBOOL
81 AC_HEADER_TIME
82
83 AC_C_BIGENDIAN
84
85 AC_CHECK_FUNCS([strndup])
86 AC_CHECK_FUNCS([strnlen])
87 AC_CHECK_FUNCS([gettimeofday])
88 AC_CHECK_FUNCS([usleep])
89 AC_CHECK_FUNCS([vasprintf])
90 AC_CHECK_FUNCS([realpath])
91
92 # guess-rev.sh only exists in the repository, not in the released archives
93 AC_MSG_CHECKING([whether to build a release])
94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
95   build_release=no
96 ], [
97   build_release=yes
98 ])
99 AC_MSG_RESULT([$build_release])
100
101 # Adapter drivers
102 # 1st column -- configure option
103 # 2nd column -- description
104 # 3rd column -- symbol used for both config.h and automake
105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
110
111 m4_define([USB1_ADAPTERS],
112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
113         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
119         [[xds110], [TI XDS110 Debug Probe], [XDS110]]])
120
121 m4_define([USB_ADAPTERS],
122         [[[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
123         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
124         [[aice], [Andes JTAG Programmer], [AICE]]])
125
126 m4_define([USB0_ADAPTERS],
127         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
128         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
129         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
130
131 m4_define([HIDAPI_ADAPTERS],
132         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
133
134 m4_define([HIDAPI_USB1_ADAPTERS],
135         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
136
137 m4_define([LIBFTDI_ADAPTERS],
138         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
139         [[presto], [ASIX Presto Adapter], [PRESTO]],
140         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
141
142 m4_define([LIBJAYLINK_ADAPTERS],
143         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
144
145 m4_define([PCIE_ADAPTERS],
146         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
147
148
149 AC_ARG_ENABLE([doxygen-html],
150   AS_HELP_STRING([--disable-doxygen-html],
151     [Disable building Doxygen manual as HTML.]),
152   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
153 AC_SUBST([doxygen_as_html])
154 AC_MSG_CHECKING([whether to build Doxygen as HTML])
155 AC_MSG_RESULT([$doxygen_as_html])
156
157 AC_ARG_ENABLE([doxygen-pdf],
158   AS_HELP_STRING([--enable-doxygen-pdf],
159     [Enable building Doxygen manual as PDF.]),
160   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
161 AC_SUBST([doxygen_as_pdf])
162 AC_MSG_CHECKING([whether to build Doxygen as PDF])
163 AC_MSG_RESULT([$doxygen_as_pdf])
164
165 AC_ARG_ENABLE([gccwarnings],
166   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
167   [gcc_warnings=$enableval], [gcc_warnings=yes])
168
169 AC_ARG_ENABLE([wextra],
170   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
171   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
172
173 AC_ARG_ENABLE([werror],
174   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
175   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
176
177 # set default verbose options, overridden by following options
178 debug_usb_io=no
179 debug_usb_comms=no
180
181 AC_ARG_ENABLE([verbose],
182   AS_HELP_STRING([--enable-verbose],
183       [Enable verbose JTAG I/O messages (for debugging).]),
184   [
185   debug_usb_io=$enableval
186   debug_usb_comms=$enableval
187   ], [])
188
189 AC_ARG_ENABLE([verbose_usb_io],
190   AS_HELP_STRING([--enable-verbose-usb-io],
191       [Enable verbose USB I/O messages (for debugging)]),
192   [debug_usb_io=$enableval], [])
193
194 AC_ARG_ENABLE([verbose_usb_comms],
195   AS_HELP_STRING([--enable-verbose-usb-comms],
196       [Enable verbose USB communication messages (for debugging)]),
197   [debug_usb_comms=$enableval], [])
198
199 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
200 AC_MSG_RESULT([$debug_usb_io])
201 AS_IF([test "x$debug_usb_io" = "xyes"], [
202   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
203 ])
204
205 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
206 AC_MSG_RESULT([$debug_usb_comms])
207 AS_IF([test "x$debug_usb_comms" = "xyes"], [
208   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
209 ])
210
211 debug_malloc=no
212 AC_ARG_ENABLE([malloc_logging],
213   AS_HELP_STRING([--enable-malloc-logging],
214       [Include free space in logging messages (requires malloc.h).]),
215   [debug_malloc=$enableval], [])
216
217 AC_MSG_CHECKING([whether to enable malloc free space logging]);
218 AC_MSG_RESULT([$debug_malloc])
219 AS_IF([test "x$debug_malloc" = "xyes"], [
220   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
221 ])
222
223 AC_ARG_ENABLE([dummy],
224   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
225   [build_dummy=$enableval], [build_dummy=no])
226
227 m4_define([AC_ARG_ADAPTERS], [
228   m4_foreach([adapter], [$1],
229         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
230                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
231                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
232                 [], [ADAPTER_VAR([adapter])=$2])
233   ])
234 ])
235
236 AC_ARG_ADAPTERS([
237   USB1_ADAPTERS,
238   USB_ADAPTERS,
239   USB0_ADAPTERS,
240   HIDAPI_ADAPTERS,
241   HIDAPI_USB1_ADAPTERS,
242   LIBFTDI_ADAPTERS,
243   LIBJAYLINK_ADAPTERS
244   ],[auto])
245
246 AC_ARG_ENABLE([parport],
247   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
248   [build_parport=$enableval], [build_parport=no])
249
250 AC_ARG_ENABLE([parport_ppdev],
251   AS_HELP_STRING([--disable-parport-ppdev],
252       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
253     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
254
255 AC_ARG_ENABLE([parport_giveio],
256     AS_HELP_STRING([--enable-parport-giveio],
257       [Enable use of giveio for parport (for CygWin only)]),
258     [parport_use_giveio=$enableval], [parport_use_giveio=])
259
260 AC_ARG_ENABLE([jtag_vpi],
261   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
262   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
263
264 AC_ARG_ENABLE([amtjtagaccel],
265   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
266   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
267
268 AC_ARG_ENABLE([zy1000_master],
269   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
270   [build_zy1000_master=$enableval], [build_zy1000_master=no])
271
272 AC_ARG_ENABLE([zy1000],
273   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
274   [build_zy1000=$enableval], [build_zy1000=no])
275
276 AC_ARG_ENABLE([ioutil],
277   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
278   [build_ioutil=$enableval], [build_ioutil=no])
279
280 AS_CASE(["${host_cpu}"],
281   [arm*], [
282     AC_ARG_ENABLE([ep93xx],
283       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
284       [build_ep93xx=$enableval], [build_ep93xx=no])
285
286     AC_ARG_ENABLE([at91rm9200],
287       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
288       [build_at91rm9200=$enableval], [build_at91rm9200=no])
289
290     AC_ARG_ENABLE([bcm2835gpio],
291       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
292       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
293     AC_ARG_ENABLE([imx_gpio],
294       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
295       [build_imx_gpio=$enableval], [build_imx_gpio=no])
296   ],
297   [
298     build_ep93xx=no
299     build_at91rm9200=no
300     build_bcm2835gpio=no
301     build_imx_gpio=no
302 ])
303
304 AC_ARG_ENABLE([gw16012],
305   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
306   [build_gw16012=$enableval], [build_gw16012=no])
307
308 AC_ARG_ENABLE([oocd_trace],
309   AS_HELP_STRING([--enable-oocd_trace],
310   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
311   [build_oocd_trace=$enableval], [build_oocd_trace=no])
312
313 AC_ARG_ENABLE([buspirate],
314   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
315   [build_buspirate=$enableval], [build_buspirate=no])
316
317 AC_ARG_ENABLE([sysfsgpio],
318   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
319   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
320
321 AC_ARG_ENABLE([xlnx_pcie_xvc],
322   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
323   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
324
325 AS_CASE([$host_os],
326   [linux*], [],
327   [
328     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
329       AC_MSG_ERROR([sysfsgpio is only available on linux])
330     ])
331
332     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
333       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
334     ])
335 ])
336
337 AC_ARG_ENABLE([minidriver_dummy],
338   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
339   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
340
341 AC_ARG_ENABLE([internal-jimtcl],
342   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
343   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
344
345 AC_ARG_ENABLE([internal-libjaylink],
346   AS_HELP_STRING([--disable-internal-libjaylink],
347   [Disable building internal libjaylink]),
348   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
349
350 AC_ARG_ENABLE([target64],
351   AS_HELP_STRING([--disable-target64], [Disable 64-bit target address]),
352     [build_target64=$enableval], [build_target64=yes])
353
354 build_minidriver=no
355 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
356 AS_IF([test "x$build_zy1000" = "xyes"], [
357   AS_IF([test "x$build_minidriver" = "xyes"], [
358     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
359   ])
360   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
361       [Define to 1 if you have the <jtag_minidriver.h> header file.])
362   build_minidriver=yes
363 ])
364 AC_MSG_RESULT([$build_zy1000])
365
366 AC_ARG_ENABLE([remote-bitbang],
367   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
368   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
369
370 AC_MSG_CHECKING([whether to enable dummy minidriver])
371 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
372   AS_IF([test "x$build_minidriver" = "xyes"], [
373     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
374   ])
375   build_minidriver=yes
376   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
377   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
378       [Define to 1 if you have the <jtag_minidriver.h> header file.])
379 ])
380 AC_MSG_RESULT([$build_minidriver_dummy])
381
382 AC_MSG_CHECKING([whether standard drivers can be built])
383 AS_IF([test "x$build_minidriver" = "xyes"], [
384   AC_MSG_RESULT([no])
385   AC_MSG_WARN([Using the minidriver disables all other drivers.])
386   sleep 2
387 ], [
388   AC_MSG_RESULT([yes])
389 ])
390
391 AS_CASE(["${host_cpu}"],
392   [i?86|x86*], [],
393   [
394     AS_IF([test "x$parport_use_ppdev" = "xno"], [
395       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
396     ])
397     parport_use_ppdev=yes
398 ])
399
400 AS_CASE([$host],
401   [*-cygwin*], [
402     is_win32=yes
403     parport_use_ppdev=no
404
405     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
406       [is_mingw=yes],[is_mingw=no])
407     AS_IF([test "x$is_mingw" = "xyes"], [
408       AS_IF([test "x$parport_use_giveio" = "xno"], [
409         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
410       ])
411       parport_use_giveio=yes
412       is_cygwin=no
413     ], [
414       is_cygwin=yes
415       # sys/io.h needed under cygwin for parport access
416       AS_IF([test "x$build_parport" = "xyes"], [
417         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
418       ])
419     ])
420   ],
421   [*-mingw* | *-msys*], [
422     is_mingw=yes
423     is_win32=yes
424     parport_use_ppdev=no
425
426     AS_IF([test "x$parport_use_giveio" = "xno"], [
427       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
428     ])
429     parport_use_giveio=yes
430
431     AS_IF([test "x$build_buspirate" = "xyes"], [
432       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
433     ])
434
435     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
436   ],
437   [*darwin*], [
438     is_darwin=yes
439
440     AS_IF([test "x$parport_use_giveio" = "xyes"], [
441       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
442     ])
443     parport_use_giveio=no
444   ],
445   [
446     AS_IF([test "x$parport_use_giveio" = "xyes"], [
447       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
448     ])
449     parport_use_giveio=no
450 ])
451
452 AS_IF([test "x$is_cygwin" = "xyes"], [
453     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
454 ], [
455     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
456 ])
457
458 AS_IF([test "x$is_mingw" = "xyes"], [
459     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
460 ], [
461     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
462 ])
463
464 AS_IF([test "x$is_win32" = "xyes"], [
465     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
466 ], [
467     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
468 ])
469
470 AS_IF([test "x$is_darwin" = "xyes"], [
471     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
472 ], [
473     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
474 ])
475
476 AS_IF([test "x$build_parport" = "xyes"], [
477   build_bitbang=yes
478   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
479 ], [
480   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
481 ])
482
483 AS_IF([test "x$build_dummy" = "xyes"], [
484   build_bitbang=yes
485   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
486 ], [
487   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
488 ])
489
490 AS_IF([test "x$build_ep93xx" = "xyes"], [
491   build_bitbang=yes
492   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
493 ], [
494   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
495 ])
496
497 AS_IF([test "x$build_zy1000" = "xyes"], [
498   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
499 ], [
500   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
501 ])
502
503 AS_IF([test "x$build_zy1000_master" = "xyes"], [
504   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
505 ], [
506   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
507 ])
508
509 AS_IF([test "x$build_at91rm9200" = "xyes"], [
510   build_bitbang=yes
511   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
512 ], [
513   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
514 ])
515
516 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
517   build_bitbang=yes
518   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
519 ], [
520   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
521 ])
522
523 AS_IF([test "x$build_imx_gpio" = "xyes"], [
524   build_bitbang=yes
525   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
526 ], [
527   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
528 ])
529
530 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
531   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
532 ], [
533   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
534 ])
535
536 AS_IF([test "x$parport_use_giveio" = "xyes"], [
537   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
538 ], [
539   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
540 ])
541
542 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
543   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
544 ], [
545   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
546 ])
547
548 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
549   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
550 ], [
551   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
552 ])
553
554 AS_IF([test "x$build_gw16012" = "xyes"], [
555   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
556 ], [
557   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
558 ])
559
560 AS_IF([test "x$build_oocd_trace" = "xyes"], [
561   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
562 ], [
563   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
564 ])
565
566 AS_IF([test "x$build_buspirate" = "xyes"], [
567   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
568 ], [
569   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
570 ])
571
572 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
573   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
574     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
575   ], [
576     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
577   ])
578 ])
579
580 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
581   build_bitbang=yes
582   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
583 ], [
584   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
585 ])
586
587 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
588   build_bitbang=yes
589   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
590 ], [
591   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
592 ])
593
594 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
595   build_xlnx_pcie_xvc=yes
596   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
597 ], [
598   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
599 ])
600
601 AS_IF([test "x$build_target64" = "xyes"], [
602   AC_DEFINE([BUILD_TARGET64], [1], [1 if you want 64-bit addresses.])
603 ], [
604   AC_DEFINE([BUILD_TARGET64], [0], [0 if you don't want 64-bit addresses.])
605 ])
606
607
608 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
609         use_libusb1=yes
610         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
611         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
612                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
613                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
614         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
615         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
616         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
617                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
618   ], [
619         use_libusb1=no
620         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
621 ])
622
623 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
624
625 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
626         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
627                 use_hidapi=yes
628                 break
629         ],[
630                 use_hidapi=no
631         ])
632 done
633
634 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
635         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
636 ])
637
638 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
639         [use_libjaylink=yes], [use_libjaylink=no])
640
641 m4_define([PROCESS_ADAPTERS], [
642   m4_foreach([adapter], [$1], [
643         AS_IF([test "x$build_zy1000" = "xyes"], [
644                 ADAPTER_VAR([adapter])=no
645         ])
646         AS_IF([test $2], [
647                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
648                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
649                 ], [
650                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
651                 ])
652         ], [
653                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
654                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
655                 ])
656                 ADAPTER_VAR([adapter])=no
657         ])
658         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
659   ])
660 ])
661
662 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
663 PROCESS_ADAPTERS([USB_ADAPTERS], ["x$use_libusb1" = "xyes" -o "x$use_libusb0" = "xyes"], [libusb-1.x or libusb-0.1])
664 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
665 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
666 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
667 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
668 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
669
670 AS_IF([test "x$build_openjtag" = "xyes"], [
671   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
672     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
673     build_openjtag=no
674   ])
675 ])
676
677 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
678         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
679 ], [
680         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
681 ])
682 AM_CONDITIONAL([HLADAPTER], [test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"])
683
684 AS_IF([test "x$enable_jlink" != "xno"], [
685   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
686     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
687       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
688                 [--enable-subproject-build])
689     ], [
690       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
691     ])
692   ])
693 ])
694
695 # Presto needs the bitq module
696 AS_IF([test "x$enable_presto" != "xno"], [
697   build_bitq=yes
698 ])
699
700 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
701 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
702 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
703 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
704 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
705 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
706 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
707 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
708 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
709 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
710 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
711 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
712 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
713 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
714 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
715 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
716 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
717 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
718 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
719 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
720 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
721 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
722 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
723 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
724 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
725 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
726 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
727 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
728 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
729 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
730 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
731 AM_CONDITIONAL([TARGET64], [test "x$build_target64" = "xyes"])
732
733 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
734 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
735
736 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
737 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
738
739 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
740 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
741 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
742 #define _GNU_SOURCE
743 #include <unistd.h>
744 #include <stdlib.h>
745   ]], [[char **ep = environ;]]
746   )], [
747     AC_MSG_RESULT([yes])
748     has_environ=yes
749   ], [
750     AC_MSG_RESULT([no])
751
752     # Possibility #2: can environ be found in an available library?
753     AC_MSG_CHECKING([for extern environ])
754     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
755     extern char **environ;
756     ]], [[char **ep = environ;]]
757       )], [
758         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
759         has_environ=yes
760       ], [
761         has_environ=no
762       ])
763     AC_MSG_RESULT([${has_environ}])
764   ])
765
766 AS_IF([test "x${has_environ}" != "xyes" ], [
767   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
768 ])
769
770 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
771
772 # set default gcc warnings
773 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
774 AS_IF([test "x${gcc_wextra}" = "xyes"], [
775   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
776   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
777   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
778   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
779 ])
780 AS_IF([test "x${gcc_werror}" = "xyes"], [
781   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
782 ])
783
784 # override default gcc cflags
785 AS_IF([test "x$gcc_warnings" = "xyes"], [
786   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
787 ])
788
789 AC_CONFIG_FILES([
790   Makefile
791 ])
792 AC_OUTPUT
793
794 echo
795 echo
796 echo OpenOCD configuration summary
797 echo --------------------------------------------------
798 m4_foreach([adapter], [USB1_ADAPTERS, USB_ADAPTERS, USB0_ADAPTERS,
799         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
800         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
801         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
802         AS_CASE([$ADAPTER_VAR([adapter])],
803                 [auto], [
804                         echo "$s"yes '(auto)'
805                 ],
806                 [yes], [
807                         echo "$s"yes
808                 ],
809                 [no], [
810                         echo "$s"no
811         ])
812 ])
813 echo
814
815 AS_IF([test "x$build_oocd_trace" = "xyes"], [
816   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
817   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
818   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
819   echo
820 ])
821
822 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
823   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
824   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
825   echo 'release. If you regularly use this platform, please report to the OpenOCD'
826   echo 'Mailing List.'
827   echo
828 ])
829
830 AS_IF([test "x$build_ioutil" = "xyes"], [
831   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
832   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
833   echo 'release. If you regularly depend on this functionality, please report to the'
834   echo 'OpenOCD Mailing List.'
835   echo
836 ])