configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG_C
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 AC_PROG_LIBTOOL
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 119         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 120         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 121         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 122         [[aice], [Andes JTAG Programmer], [AICE]]])
 123
 124 m4_define([USB0_ADAPTERS],
 125         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 126         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 127         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 128
 129 m4_define([HIDAPI_ADAPTERS],
 130         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
 131
 132 m4_define([HIDAPI_USB1_ADAPTERS],
 133         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 134
 135 m4_define([LIBFTDI_ADAPTERS],
 136         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 137         [[presto], [ASIX Presto Adapter], [PRESTO]],
 138         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 139
 140 m4_define([LIBJAYLINK_ADAPTERS],
 141         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 142
 143 m4_define([PCIE_ADAPTERS],
 144         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 145
 146
 147 AC_ARG_ENABLE([doxygen-html],
 148   AS_HELP_STRING([--disable-doxygen-html],
 149     [Disable building Doxygen manual as HTML.]),
 150   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 151 AC_SUBST([doxygen_as_html])
 152 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 153 AC_MSG_RESULT([$doxygen_as_html])
 154
 155 AC_ARG_ENABLE([doxygen-pdf],
 156   AS_HELP_STRING([--enable-doxygen-pdf],
 157     [Enable building Doxygen manual as PDF.]),
 158   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 159 AC_SUBST([doxygen_as_pdf])
 160 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 161 AC_MSG_RESULT([$doxygen_as_pdf])
 162
 163 AC_ARG_ENABLE([gccwarnings],
 164   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 165   [gcc_warnings=$enableval], [gcc_warnings=yes])
 166
 167 AC_ARG_ENABLE([wextra],
 168   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 169   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 170
 171 AC_ARG_ENABLE([werror],
 172   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 173   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 174
 175 # set default verbose options, overridden by following options
 176 debug_usb_io=no
 177 debug_usb_comms=no
 178
 179 AC_ARG_ENABLE([verbose],
 180   AS_HELP_STRING([--enable-verbose],
 181       [Enable verbose JTAG I/O messages (for debugging).]),
 182   [
 183   debug_usb_io=$enableval
 184   debug_usb_comms=$enableval
 185   ], [])
 186
 187 AC_ARG_ENABLE([verbose_usb_io],
 188   AS_HELP_STRING([--enable-verbose-usb-io],
 189       [Enable verbose USB I/O messages (for debugging)]),
 190   [debug_usb_io=$enableval], [])
 191
 192 AC_ARG_ENABLE([verbose_usb_comms],
 193   AS_HELP_STRING([--enable-verbose-usb-comms],
 194       [Enable verbose USB communication messages (for debugging)]),
 195   [debug_usb_comms=$enableval], [])
 196
 197 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 198 AC_MSG_RESULT([$debug_usb_io])
 199 AS_IF([test "x$debug_usb_io" = "xyes"], [
 200   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 201 ])
 202
 203 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 204 AC_MSG_RESULT([$debug_usb_comms])
 205 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 206   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 207 ])
 208
 209 debug_malloc=no
 210 AC_ARG_ENABLE([malloc_logging],
 211   AS_HELP_STRING([--enable-malloc-logging],
 212       [Include free space in logging messages (requires malloc.h).]),
 213   [debug_malloc=$enableval], [])
 214
 215 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 216 AC_MSG_RESULT([$debug_malloc])
 217 AS_IF([test "x$debug_malloc" = "xyes"], [
 218   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 219 ])
 220
 221 AC_ARG_ENABLE([dummy],
 222   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 223   [build_dummy=$enableval], [build_dummy=no])
 224
 225 AS_CASE([$host_os], [linux*], [host_os_linux=yes], [host_os_linux=no])
 226
 227 AC_ARG_ENABLE([rshim],
 228   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 229   [build_rshim=$enableval], [build_rshim=$host_os_linux])
 230
 231 m4_define([AC_ARG_ADAPTERS], [
 232   m4_foreach([adapter], [$1],
 233         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 234                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 235                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 236                 [], [ADAPTER_VAR([adapter])=$2])
 237   ])
 238 ])
 239
 240 AC_ARG_ADAPTERS([
 241   USB1_ADAPTERS,
 242   USB0_ADAPTERS,
 243   HIDAPI_ADAPTERS,
 244   HIDAPI_USB1_ADAPTERS,
 245   LIBFTDI_ADAPTERS,
 246   LIBJAYLINK_ADAPTERS
 247   ],[auto])
 248
 249 AC_ARG_ENABLE([parport],
 250   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 251   [build_parport=$enableval], [build_parport=no])
 252
 253 AC_ARG_ENABLE([parport_ppdev],
 254   AS_HELP_STRING([--disable-parport-ppdev],
 255       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 256     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 257
 258 AC_ARG_ENABLE([parport_giveio],
 259     AS_HELP_STRING([--enable-parport-giveio],
 260       [Enable use of giveio for parport (for CygWin only)]),
 261     [parport_use_giveio=$enableval], [parport_use_giveio=])
 262
 263 AC_ARG_ENABLE([jtag_vpi],
 264   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 265   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 266
 267 AC_ARG_ENABLE([amtjtagaccel],
 268   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 269   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 270
 271 AC_ARG_ENABLE([zy1000_master],
 272   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 273   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 274
 275 AC_ARG_ENABLE([zy1000],
 276   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 277   [build_zy1000=$enableval], [build_zy1000=no])
 278
 279 AC_ARG_ENABLE([ioutil],
 280   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 281   [build_ioutil=$enableval], [build_ioutil=no])
 282
 283 AS_CASE(["${host_cpu}"],
 284   [arm*|aarch64], [
 285     AC_ARG_ENABLE([bcm2835gpio],
 286       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 287       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 288     AC_ARG_ENABLE([imx_gpio],
 289       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 290       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 291   ],
 292   [
 293     build_bcm2835gpio=no
 294     build_imx_gpio=no
 295 ])
 296
 297 AS_CASE(["${host_cpu}"],
 298   [arm*], [
 299     AC_ARG_ENABLE([ep93xx],
 300       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 301       [build_ep93xx=$enableval], [build_ep93xx=no])
 302
 303     AC_ARG_ENABLE([at91rm9200],
 304       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 305       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 306   ],
 307   [
 308     build_ep93xx=no
 309     build_at91rm9200=no
 310 ])
 311
 312 AC_ARG_ENABLE([gw16012],
 313   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 314   [build_gw16012=$enableval], [build_gw16012=no])
 315
 316 AC_ARG_ENABLE([oocd_trace],
 317   AS_HELP_STRING([--enable-oocd_trace],
 318   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 319   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 320
 321 AC_ARG_ENABLE([buspirate],
 322   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 323   [build_buspirate=$enableval], [build_buspirate=no])
 324
 325 AC_ARG_ENABLE([sysfsgpio],
 326   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 327   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 328
 329 AC_ARG_ENABLE([xlnx_pcie_xvc],
 330   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 331   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 332
 333 AS_CASE([$host_os],
 334   [linux*], [],
 335   [
 336     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 337       AC_MSG_ERROR([sysfsgpio is only available on linux])
 338     ])
 339
 340     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 341       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 342     ])
 343
 344     AS_CASE([$host_os], [freebsd*], [],
 345     [
 346       AS_IF([test "x$build_rshim" = "xyes"], [
 347         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 348       ])
 349     ])
 350 ])
 351
 352 AC_ARG_ENABLE([minidriver_dummy],
 353   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 354   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 355
 356 AC_ARG_ENABLE([internal-jimtcl],
 357   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 358   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 359
 360 AC_ARG_ENABLE([internal-libjaylink],
 361   AS_HELP_STRING([--disable-internal-libjaylink],
 362   [Disable building internal libjaylink]),
 363   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 364
 365 AC_ARG_ENABLE([target64],
 366   AS_HELP_STRING([--disable-target64], [Disable 64-bit target address]),
 367     [build_target64=$enableval], [build_target64=yes])
 368
 369 build_minidriver=no
 370 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 371 AS_IF([test "x$build_zy1000" = "xyes"], [
 372   AS_IF([test "x$build_minidriver" = "xyes"], [
 373     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 374   ])
 375   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 376       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 377   build_minidriver=yes
 378 ])
 379 AC_MSG_RESULT([$build_zy1000])
 380
 381 AC_ARG_ENABLE([remote-bitbang],
 382   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 383   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 384
 385 AC_MSG_CHECKING([whether to enable dummy minidriver])
 386 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 387   AS_IF([test "x$build_minidriver" = "xyes"], [
 388     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 389   ])
 390   build_minidriver=yes
 391   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 392   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 393       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 394 ])
 395 AC_MSG_RESULT([$build_minidriver_dummy])
 396
 397 AC_MSG_CHECKING([whether standard drivers can be built])
 398 AS_IF([test "x$build_minidriver" = "xyes"], [
 399   AC_MSG_RESULT([no])
 400   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 401   sleep 2
 402 ], [
 403   AC_MSG_RESULT([yes])
 404 ])
 405
 406 AS_CASE(["${host_cpu}"],
 407   [i?86|x86*], [],
 408   [
 409     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 410       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 411     ])
 412     parport_use_ppdev=yes
 413 ])
 414
 415 AS_CASE([$host],
 416   [*-cygwin*], [
 417     is_win32=yes
 418     parport_use_ppdev=no
 419
 420     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 421       [is_mingw=yes],[is_mingw=no])
 422     AS_IF([test "x$is_mingw" = "xyes"], [
 423       AS_IF([test "x$parport_use_giveio" = "xno"], [
 424         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 425       ])
 426       parport_use_giveio=yes
 427       is_cygwin=no
 428     ], [
 429       is_cygwin=yes
 430       # sys/io.h needed under cygwin for parport access
 431       AS_IF([test "x$build_parport" = "xyes"], [
 432         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 433       ])
 434     ])
 435   ],
 436   [*-mingw* | *-msys*], [
 437     is_mingw=yes
 438     is_win32=yes
 439     parport_use_ppdev=no
 440
 441     AS_IF([test "x$parport_use_giveio" = "xno"], [
 442       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 443     ])
 444     parport_use_giveio=yes
 445
 446     AS_IF([test "x$build_buspirate" = "xyes"], [
 447       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 448     ])
 449
 450     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 451   ],
 452   [*darwin*], [
 453     is_darwin=yes
 454
 455     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 456       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 457     ])
 458     parport_use_giveio=no
 459   ],
 460   [
 461     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 462       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 463     ])
 464     parport_use_giveio=no
 465 ])
 466
 467 AS_IF([test "x$is_cygwin" = "xyes"], [
 468     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 469 ], [
 470     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 471 ])
 472
 473 AS_IF([test "x$is_mingw" = "xyes"], [
 474     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 475 ], [
 476     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 477 ])
 478
 479 AS_IF([test "x$is_win32" = "xyes"], [
 480     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 481 ], [
 482     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 483 ])
 484
 485 AS_IF([test "x$is_darwin" = "xyes"], [
 486     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 487 ], [
 488     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 489 ])
 490
 491 AS_IF([test "x$build_parport" = "xyes"], [
 492   build_bitbang=yes
 493   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 494 ], [
 495   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 496 ])
 497
 498 AS_IF([test "x$build_rshim" = "xyes"], [
 499   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 500 ], [
 501   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 502 ])
 503
 504 AS_IF([test "x$build_dummy" = "xyes"], [
 505   build_bitbang=yes
 506   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 507 ], [
 508   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 509 ])
 510
 511 AS_IF([test "x$build_ep93xx" = "xyes"], [
 512   build_bitbang=yes
 513   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 514 ], [
 515   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 516 ])
 517
 518 AS_IF([test "x$build_zy1000" = "xyes"], [
 519   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 520 ], [
 521   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 522 ])
 523
 524 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 525   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 526 ], [
 527   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 528 ])
 529
 530 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 531   build_bitbang=yes
 532   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 533 ], [
 534   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 535 ])
 536
 537 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 538   build_bitbang=yes
 539   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 540 ], [
 541   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 542 ])
 543
 544 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 545   build_bitbang=yes
 546   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 547 ], [
 548   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 549 ])
 550
 551 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 552   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 553 ], [
 554   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 555 ])
 556
 557 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 558   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 559 ], [
 560   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 561 ])
 562
 563 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 564   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 565 ], [
 566   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 567 ])
 568
 569 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 570   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 571 ], [
 572   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 573 ])
 574
 575 AS_IF([test "x$build_gw16012" = "xyes"], [
 576   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 577 ], [
 578   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 579 ])
 580
 581 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 582   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 583 ], [
 584   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 585 ])
 586
 587 AS_IF([test "x$build_buspirate" = "xyes"], [
 588   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 589 ], [
 590   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 591 ])
 592
 593 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 594   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 595     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 596   ], [
 597     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 598   ])
 599 ])
 600
 601 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 602   build_bitbang=yes
 603   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 604 ], [
 605   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 606 ])
 607
 608 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 609   build_bitbang=yes
 610   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 611 ], [
 612   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 613 ])
 614
 615 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 616   build_xlnx_pcie_xvc=yes
 617   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 618 ], [
 619   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 620 ])
 621
 622 AS_IF([test "x$build_target64" = "xyes"], [
 623   AC_DEFINE([BUILD_TARGET64], [1], [1 if you want 64-bit addresses.])
 624 ], [
 625   AC_DEFINE([BUILD_TARGET64], [0], [0 if you don't want 64-bit addresses.])
 626 ])
 627
 628
 629 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 630         use_libusb1=yes
 631         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 632         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 633                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 634                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 635         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 636         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 637         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 638                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 639   ], [
 640         use_libusb1=no
 641         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 642 ])
 643
 644 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 645
 646 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 647         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 648                 use_hidapi=yes
 649                 break
 650         ],[
 651                 use_hidapi=no
 652         ])
 653 done
 654
 655 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 656         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 657 ])
 658
 659 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 660         [use_libjaylink=yes], [use_libjaylink=no])
 661
 662 m4_define([PROCESS_ADAPTERS], [
 663   m4_foreach([adapter], [$1], [
 664         AS_IF([test "x$build_zy1000" = "xyes"], [
 665                 ADAPTER_VAR([adapter])=no
 666         ])
 667         AS_IF([test $2], [
 668                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 669                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 670                 ], [
 671                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 672                 ])
 673         ], [
 674                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 675                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 676                 ])
 677                 ADAPTER_VAR([adapter])=no
 678         ])
 679         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 680   ])
 681 ])
 682
 683 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 684 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 685 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 686 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 687 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 688 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 689
 690 AS_IF([test "x$build_openjtag" = "xyes"], [
 691   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 692     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 693     build_openjtag=no
 694   ])
 695 ])
 696
 697 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
 698         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 699 ], [
 700         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 701 ])
 702 AM_CONDITIONAL([HLADAPTER], [test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"])
 703
 704 AS_IF([test "x$enable_jlink" != "xno"], [
 705   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 706     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 707       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 708                 [--enable-subproject-build])
 709     ], [
 710       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 711     ])
 712   ])
 713 ])
 714
 715 # Presto needs the bitq module
 716 AS_IF([test "x$enable_presto" != "xno"], [
 717   build_bitq=yes
 718 ])
 719
 720 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 721 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 722 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 723 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 724 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 725 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 726 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 727 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 728 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 729 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 730 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 731 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 732 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 733 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 734 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 735 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 736 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 737 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 738 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 739 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 740 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 741 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 742 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 743 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 744 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 745 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 746 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 747 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 748 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 749 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 750 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 751 AM_CONDITIONAL([TARGET64], [test "x$build_target64" = "xyes"])
 752 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 753
 754 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 755 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 756
 757 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 758 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 759
 760 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 761 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 762 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 763 #define _GNU_SOURCE
 764 #include <unistd.h>
 765 #include <stdlib.h>
 766   ]], [[char **ep = environ;]]
 767   )], [
 768     AC_MSG_RESULT([yes])
 769     has_environ=yes
 770   ], [
 771     AC_MSG_RESULT([no])
 772
 773     # Possibility #2: can environ be found in an available library?
 774     AC_MSG_CHECKING([for extern environ])
 775     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 776     extern char **environ;
 777     ]], [[char **ep = environ;]]
 778       )], [
 779         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 780         has_environ=yes
 781       ], [
 782         has_environ=no
 783       ])
 784     AC_MSG_RESULT([${has_environ}])
 785   ])
 786
 787 AS_IF([test "x${has_environ}" != "xyes" ], [
 788   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 789 ])
 790
 791 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 792
 793 # set default gcc warnings
 794 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 795 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 796   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 797   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 798   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 799   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 800 ])
 801 AS_IF([test "x${gcc_werror}" = "xyes"], [
 802   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 803 ])
 804
 805 # override default gcc cflags
 806 AS_IF([test "x$gcc_warnings" = "xyes"], [
 807   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 808 ])
 809
 810 AC_CONFIG_FILES([
 811   Makefile
 812 ])
 813 AC_OUTPUT
 814
 815 echo
 816 echo
 817 echo OpenOCD configuration summary
 818 echo --------------------------------------------------
 819 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 820         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 821         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
 822         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 823         AS_CASE([$ADAPTER_VAR([adapter])],
 824                 [auto], [
 825                         echo "$s"yes '(auto)'
 826                 ],
 827                 [yes], [
 828                         echo "$s"yes
 829                 ],
 830                 [no], [
 831                         echo "$s"no
 832         ])
 833 ])
 834 echo
 835
 836 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 837   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 838   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 839   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 840   echo
 841 ])
 842
 843 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 844   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 845   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 846   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 847   echo 'Mailing List.'
 848   echo
 849 ])
 850
 851 AS_IF([test "x$build_ioutil" = "xyes"], [
 852   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 853   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 854   echo 'release. If you regularly depend on this functionality, please report to the'
 855   echo 'OpenOCD Mailing List.'
 856   echo
 857 ])