AM335x: Disable watchdog on 'reset halt'
[openocd.git] / tcl / target / am335x.cfg
1 source [find target/icepick.cfg]
2
3 if { [info exists CHIPNAME] } {
4         set _CHIPNAME $CHIPNAME
5 } else {
6         set _CHIPNAME am335x
7 }
8
9 # set the taps to be enabled by default. this can be overridden
10 # by setting DEFAULT_TAPS in a separate configuration file
11 # or directly on the command line.
12 if { [info exists DEFAULT_TAPS] } {
13         set _DEFAULT_TAPS "$DEFAULT_TAPS"
14 } else {
15         set _DEFAULT_TAPS "$_CHIPNAME.dap"
16 }
17
18 #
19 # Main DAP
20 #
21 if { [info exists DAP_TAPID] } {
22         set _DAP_TAPID $DAP_TAPID
23 } else {
24         set _DAP_TAPID 0x4b6b902f
25 }
26 jtag newtap $_CHIPNAME dap -irlen 4 -ircapture 0x1 -irmask 0xf -expected-id $_DAP_TAPID -disable
27 jtag configure $_CHIPNAME.dap -event tap-enable "icepick_d_tapenable $_CHIPNAME.jrc 12 0"
28
29 #
30 # M3 DAP
31 #
32 if { [info exists M3_DAP_TAPID] } {
33         set _M3_DAP_TAPID $M3_DAP_TAPID
34 } else {
35         set _M3_DAP_TAPID 0x4b6b902f
36 }
37 jtag newtap $_CHIPNAME m3_dap -irlen 4 -ircapture 0x1 -irmask 0xf -expected-id $_M3_DAP_TAPID -disable
38 jtag configure $_CHIPNAME.m3_dap -event tap-enable "icepick_d_tapenable $_CHIPNAME.jrc 11 0"
39
40 #
41 # ICEpick-D (JTAG route controller)
42 #
43 if { [info exists JRC_TAPID] } {
44         set _JRC_TAPID $JRC_TAPID
45 } else {
46         set _JRC_TAPID 0x0b94402f
47 }
48 jtag newtap $_CHIPNAME jrc -irlen 6 -ircapture 0x1 -irmask 0x3f -expected-id $_JRC_TAPID -ignore-version
49 jtag configure $_CHIPNAME.jrc -event setup {
50         global _DEFAULT_TAPS
51         enable_default_taps $_DEFAULT_TAPS
52 }
53 # some TCK tycles are required to activate the DEBUG power domain
54 jtag configure $_CHIPNAME.jrc -event post-reset "runtest 100"
55
56 #
57 # helper function that enables all taps passed as argument
58 #
59 proc enable_default_taps { taps } {
60         foreach tap $taps {
61                 jtag tapenable $tap
62         }
63 }
64
65 #
66 # Cortex-M3 target
67 #
68 set _TARGETNAME_2 $_CHIPNAME.m3
69 target create $_TARGETNAME_2 cortex_m -chain-position $_CHIPNAME.m3_dap
70
71 #
72 # Cortex-A8 target
73 #
74 set _TARGETNAME $_CHIPNAME.cpu
75 target create $_TARGETNAME cortex_a -chain-position $_CHIPNAME.dap -dbgbase 0x80001000
76
77 # SRAM: 64K at 0x4030.0000; use the first 16K
78 $_TARGETNAME configure -work-area-phys 0x40300000 -work-area-size 0x4000
79
80
81 # when putting the target into 'reset halt', we need to disable the watchdog as
82 # it would otherwise trigger while we're in JTAG
83 # FIXME: unify with target/am437x.cfg
84 source [find mem_helper.tcl]
85 set  WDT1_BASE_ADDR                  0x44e35000
86 set  WDT1_W_PEND_WSPR                [expr       $WDT1_BASE_ADDR     +  0x0034]
87 set  WDT1_WSPR                       [expr       $WDT1_BASE_ADDR     +  0x0048]
88 proc disable_watchdog { } {
89         global WDT1_WSPR
90         global WDT1_W_PEND_WSPR
91         global _TARGETNAME
92
93         set curstate [$_TARGETNAME curstate]
94
95         if { [string compare $curstate halted] == 0 } {
96                 set WDT_DISABLE_SEQ1    0xaaaa
97                 set WDT_DISABLE_SEQ2    0x5555
98
99                 mww phys $WDT1_WSPR $WDT_DISABLE_SEQ1
100
101                 # Empty body to make sure this executes as fast as possible.
102                 # We don't want any delays here otherwise romcode might start
103                 # executing and end up changing state of certain IPs.
104                 while { [expr [mrw $WDT1_W_PEND_WSPR] & 0x10] } { }
105
106                 mww phys $WDT1_WSPR $WDT_DISABLE_SEQ2
107                 while { [expr [mrw $WDT1_W_PEND_WSPR] & 0x10] } { }
108         }
109 }
110 $_TARGETNAME configure -event reset-end { disable_watchdog }