contrib/loaders/flash/nrf5/nrf5.S

   1 /***************************************************************************
   2  *   Copyright (C) 2014 Angus Gratton                                      *
   3  *   gus@projectgus.com                                                    *
   4  *                                                                         *
   5  *   This program is free software; you can redistribute it and/or modify  *
   6  *   it under the terms of the GNU General Public License as published by  *
   7  *   the Free Software Foundation; either version 2 of the License, or     *
   8  *   (at your option) any later version.                                   *
   9  *                                                                         *
  10  *   This program is distributed in the hope that it will be useful,       *
  11  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  12  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  13  *   GNU General Public License for more details.                          *
  14  *                                                                         *
  15  *   You should have received a copy of the GNU General Public License     *
  16  *   along with this program; if not, write to the                         *
  17  *   Free Software Foundation, Inc.                                        *
  18  ***************************************************************************/
  19
  20         .text
  21         .syntax unified
  22         .thumb
  23
  24 /*
  25  * Params :
  26  * r0 = byte count
  27  * r1 = buffer start
  28  * r2 = buffer end
  29  * r3 = target address
  30  * r6 = watchdog refresh value
  31  * r7 = watchdog refresh register address
  32  */
  33
  34         .thumb_func
  35         .global _start
  36 _start:
  37 wait_fifo:
  38         // Kick the watchdog
  39         str     r6, [r7, #0]
  40         // Load write pointer
  41         ldr     r5, [r1, #0]
  42         // Abort if it is NULL
  43         cmp     r5, #0
  44         beq.n   exit
  45         // Load read pointer
  46         ldr     r4, [r1, #4]
  47         // Continue waiting if it equals the write pointer
  48         cmp     r4, r5
  49         beq.n   wait_fifo
  50         // Copy one word from buffer to target, and increment pointers
  51         ldmia   r4!, {r5}
  52         stmia   r3!, {r5}
  53         // If at end of buffer, wrap back to buffer start
  54         cmp     r4, r2
  55         bcc.n   no_wrap
  56         mov     r4, r1
  57         adds    r4, #8
  58 no_wrap:
  59         // Update read pointer inside the buffer
  60         str     r4, [r1, #4]
  61         // Deduce the word transferred from the byte count
  62         subs    r0, #4
  63         // Start again
  64         bne.n   wait_fifo
  65 exit:
  66         // Wait for OpenOCD
  67         bkpt    #0x00
  68
  69         .pool