configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG_C
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 AC_PROG_LIBTOOL
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 119         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 120         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 121         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 122         [[aice], [Andes JTAG Programmer], [AICE]]])
 123
 124 m4_define([USB0_ADAPTERS],
 125         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 126         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 127         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 128
 129 m4_define([HIDAPI_ADAPTERS],
 130         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
 131
 132 m4_define([HIDAPI_USB1_ADAPTERS],
 133         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 134
 135 m4_define([LIBFTDI_ADAPTERS],
 136         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 137         [[presto], [ASIX Presto Adapter], [PRESTO]],
 138         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 139
 140 m4_define([LIBGPIOD_ADAPTERS],
 141         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 142
 143 m4_define([LIBJAYLINK_ADAPTERS],
 144         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 145
 146 m4_define([PCIE_ADAPTERS],
 147         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 148
 149
 150 AC_ARG_ENABLE([doxygen-html],
 151   AS_HELP_STRING([--disable-doxygen-html],
 152     [Disable building Doxygen manual as HTML.]),
 153   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 154 AC_SUBST([doxygen_as_html])
 155 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 156 AC_MSG_RESULT([$doxygen_as_html])
 157
 158 AC_ARG_ENABLE([doxygen-pdf],
 159   AS_HELP_STRING([--enable-doxygen-pdf],
 160     [Enable building Doxygen manual as PDF.]),
 161   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 162 AC_SUBST([doxygen_as_pdf])
 163 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 164 AC_MSG_RESULT([$doxygen_as_pdf])
 165
 166 AC_ARG_ENABLE([gccwarnings],
 167   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 168   [gcc_warnings=$enableval], [gcc_warnings=yes])
 169
 170 AC_ARG_ENABLE([wextra],
 171   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 172   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 173
 174 AC_ARG_ENABLE([werror],
 175   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 176   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 177
 178 # set default verbose options, overridden by following options
 179 debug_usb_io=no
 180 debug_usb_comms=no
 181
 182 AC_ARG_ENABLE([verbose],
 183   AS_HELP_STRING([--enable-verbose],
 184       [Enable verbose JTAG I/O messages (for debugging).]),
 185   [
 186   debug_usb_io=$enableval
 187   debug_usb_comms=$enableval
 188   ], [])
 189
 190 AC_ARG_ENABLE([verbose_usb_io],
 191   AS_HELP_STRING([--enable-verbose-usb-io],
 192       [Enable verbose USB I/O messages (for debugging)]),
 193   [debug_usb_io=$enableval], [])
 194
 195 AC_ARG_ENABLE([verbose_usb_comms],
 196   AS_HELP_STRING([--enable-verbose-usb-comms],
 197       [Enable verbose USB communication messages (for debugging)]),
 198   [debug_usb_comms=$enableval], [])
 199
 200 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 201 AC_MSG_RESULT([$debug_usb_io])
 202 AS_IF([test "x$debug_usb_io" = "xyes"], [
 203   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 204 ])
 205
 206 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 207 AC_MSG_RESULT([$debug_usb_comms])
 208 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 209   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 210 ])
 211
 212 debug_malloc=no
 213 AC_ARG_ENABLE([malloc_logging],
 214   AS_HELP_STRING([--enable-malloc-logging],
 215       [Include free space in logging messages (requires malloc.h).]),
 216   [debug_malloc=$enableval], [])
 217
 218 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 219 AC_MSG_RESULT([$debug_malloc])
 220 AS_IF([test "x$debug_malloc" = "xyes"], [
 221   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 222 ])
 223
 224 AC_ARG_ENABLE([dummy],
 225   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 226   [build_dummy=$enableval], [build_dummy=no])
 227
 228 AC_ARG_ENABLE([rshim],
 229   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 230   [build_rshim=$enableval], [build_rshim=no])
 231
 232 m4_define([AC_ARG_ADAPTERS], [
 233   m4_foreach([adapter], [$1],
 234         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 235                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 236                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 237                 [], [ADAPTER_VAR([adapter])=$2])
 238   ])
 239 ])
 240
 241 AC_ARG_ADAPTERS([
 242   USB1_ADAPTERS,
 243   USB0_ADAPTERS,
 244   HIDAPI_ADAPTERS,
 245   HIDAPI_USB1_ADAPTERS,
 246   LIBFTDI_ADAPTERS,
 247   LIBGPIOD_ADAPTERS,
 248   LIBJAYLINK_ADAPTERS
 249   ],[auto])
 250
 251 AC_ARG_ENABLE([parport],
 252   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 253   [build_parport=$enableval], [build_parport=no])
 254
 255 AC_ARG_ENABLE([parport_ppdev],
 256   AS_HELP_STRING([--disable-parport-ppdev],
 257       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 258     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 259
 260 AC_ARG_ENABLE([parport_giveio],
 261     AS_HELP_STRING([--enable-parport-giveio],
 262       [Enable use of giveio for parport (for CygWin only)]),
 263     [parport_use_giveio=$enableval], [parport_use_giveio=])
 264
 265 AC_ARG_ENABLE([jtag_vpi],
 266   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 267   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 268
 269 AC_ARG_ENABLE([amtjtagaccel],
 270   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 271   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 272
 273 AC_ARG_ENABLE([zy1000_master],
 274   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 275   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 276
 277 AC_ARG_ENABLE([zy1000],
 278   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 279   [build_zy1000=$enableval], [build_zy1000=no])
 280
 281 AC_ARG_ENABLE([ioutil],
 282   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 283   [build_ioutil=$enableval], [build_ioutil=no])
 284
 285 AS_CASE(["${host_cpu}"],
 286   [arm*|aarch64], [
 287     AC_ARG_ENABLE([bcm2835gpio],
 288       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 289       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 290     AC_ARG_ENABLE([imx_gpio],
 291       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 292       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 293   ],
 294   [
 295     build_bcm2835gpio=no
 296     build_imx_gpio=no
 297 ])
 298
 299 AS_CASE(["${host_cpu}"],
 300   [arm*], [
 301     AC_ARG_ENABLE([ep93xx],
 302       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 303       [build_ep93xx=$enableval], [build_ep93xx=no])
 304
 305     AC_ARG_ENABLE([at91rm9200],
 306       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 307       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 308   ],
 309   [
 310     build_ep93xx=no
 311     build_at91rm9200=no
 312 ])
 313
 314 AC_ARG_ENABLE([gw16012],
 315   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 316   [build_gw16012=$enableval], [build_gw16012=no])
 317
 318 AC_ARG_ENABLE([oocd_trace],
 319   AS_HELP_STRING([--enable-oocd_trace],
 320   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 321   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 322
 323 AC_ARG_ENABLE([buspirate],
 324   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 325   [build_buspirate=$enableval], [build_buspirate=no])
 326
 327 AC_ARG_ENABLE([sysfsgpio],
 328   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 329   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 330
 331 AC_ARG_ENABLE([xlnx_pcie_xvc],
 332   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 333   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 334
 335 AS_CASE([$host_os],
 336   [linux*], [],
 337   [
 338     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 339       AC_MSG_ERROR([sysfsgpio is only available on linux])
 340     ])
 341
 342     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 343       AC_MSG_ERROR([linuxgpiod is only available on linux])
 344     ])
 345
 346     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 347       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 348     ])
 349
 350     AS_CASE([$host_os], [freebsd*], [],
 351     [
 352       AS_IF([test "x$build_rshim" = "xyes"], [
 353         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 354       ])
 355     ])
 356 ])
 357
 358 AC_ARG_ENABLE([minidriver_dummy],
 359   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 360   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 361
 362 AC_ARG_ENABLE([internal-jimtcl],
 363   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 364   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 365
 366 AC_ARG_ENABLE([internal-libjaylink],
 367   AS_HELP_STRING([--disable-internal-libjaylink],
 368   [Disable building internal libjaylink]),
 369   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 370
 371 build_minidriver=no
 372 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 373 AS_IF([test "x$build_zy1000" = "xyes"], [
 374   AS_IF([test "x$build_minidriver" = "xyes"], [
 375     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 376   ])
 377   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 378       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 379   build_minidriver=yes
 380 ])
 381 AC_MSG_RESULT([$build_zy1000])
 382
 383 AC_ARG_ENABLE([remote-bitbang],
 384   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 385   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 386
 387 AC_MSG_CHECKING([whether to enable dummy minidriver])
 388 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 389   AS_IF([test "x$build_minidriver" = "xyes"], [
 390     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 391   ])
 392   build_minidriver=yes
 393   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 394   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 395       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 396 ])
 397 AC_MSG_RESULT([$build_minidriver_dummy])
 398
 399 AC_MSG_CHECKING([whether standard drivers can be built])
 400 AS_IF([test "x$build_minidriver" = "xyes"], [
 401   AC_MSG_RESULT([no])
 402   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 403   sleep 2
 404 ], [
 405   AC_MSG_RESULT([yes])
 406 ])
 407
 408 AS_CASE(["${host_cpu}"],
 409   [i?86|x86*], [],
 410   [
 411     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 412       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 413     ])
 414     parport_use_ppdev=yes
 415 ])
 416
 417 AS_CASE([$host],
 418   [*-cygwin*], [
 419     is_win32=yes
 420     parport_use_ppdev=no
 421
 422     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 423       [is_mingw=yes],[is_mingw=no])
 424     AS_IF([test "x$is_mingw" = "xyes"], [
 425       AS_IF([test "x$parport_use_giveio" = "xno"], [
 426         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 427       ])
 428       parport_use_giveio=yes
 429       is_cygwin=no
 430     ], [
 431       is_cygwin=yes
 432       # sys/io.h needed under cygwin for parport access
 433       AS_IF([test "x$build_parport" = "xyes"], [
 434         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 435       ])
 436     ])
 437   ],
 438   [*-mingw* | *-msys*], [
 439     is_mingw=yes
 440     is_win32=yes
 441     parport_use_ppdev=no
 442
 443     AS_IF([test "x$parport_use_giveio" = "xno"], [
 444       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 445     ])
 446     parport_use_giveio=yes
 447
 448     AS_IF([test "x$build_buspirate" = "xyes"], [
 449       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 450     ])
 451
 452     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 453   ],
 454   [*darwin*], [
 455     is_darwin=yes
 456
 457     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 458       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 459     ])
 460     parport_use_giveio=no
 461   ],
 462   [
 463     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 464       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 465     ])
 466     parport_use_giveio=no
 467 ])
 468
 469 AS_IF([test "x$is_cygwin" = "xyes"], [
 470     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 471 ], [
 472     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 473 ])
 474
 475 AS_IF([test "x$is_mingw" = "xyes"], [
 476     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 477 ], [
 478     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 479 ])
 480
 481 AS_IF([test "x$is_win32" = "xyes"], [
 482     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 483 ], [
 484     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 485 ])
 486
 487 AS_IF([test "x$is_darwin" = "xyes"], [
 488     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 489 ], [
 490     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 491 ])
 492
 493 AS_IF([test "x$build_parport" = "xyes"], [
 494   build_bitbang=yes
 495   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 496 ], [
 497   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 498 ])
 499
 500 AS_IF([test "x$build_rshim" = "xyes"], [
 501   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 502 ], [
 503   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 504 ])
 505
 506 AS_IF([test "x$build_dummy" = "xyes"], [
 507   build_bitbang=yes
 508   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 509 ], [
 510   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 511 ])
 512
 513 AS_IF([test "x$build_ep93xx" = "xyes"], [
 514   build_bitbang=yes
 515   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 516 ], [
 517   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 518 ])
 519
 520 AS_IF([test "x$build_zy1000" = "xyes"], [
 521   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 522 ], [
 523   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 524 ])
 525
 526 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 527   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 528 ], [
 529   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 530 ])
 531
 532 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 533   build_bitbang=yes
 534   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 535 ], [
 536   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 537 ])
 538
 539 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 540   build_bitbang=yes
 541   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 542 ], [
 543   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 544 ])
 545
 546 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 547   build_bitbang=yes
 548   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 549 ], [
 550   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 551 ])
 552
 553 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 554   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 555 ], [
 556   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 557 ])
 558
 559 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 560   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 561 ], [
 562   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 563 ])
 564
 565 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 566   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 567 ], [
 568   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 569 ])
 570
 571 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 572   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 573 ], [
 574   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 575 ])
 576
 577 AS_IF([test "x$build_gw16012" = "xyes"], [
 578   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 579 ], [
 580   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 581 ])
 582
 583 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 584   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 585 ], [
 586   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 587 ])
 588
 589 AS_IF([test "x$build_buspirate" = "xyes"], [
 590   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 591 ], [
 592   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 593 ])
 594
 595 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 596   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 597     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 598   ], [
 599     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 600   ])
 601 ])
 602
 603 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 604   build_bitbang=yes
 605   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 606 ], [
 607   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 608 ])
 609
 610 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 611   build_bitbang=yes
 612   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 613 ], [
 614   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 615 ])
 616
 617 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 618   build_xlnx_pcie_xvc=yes
 619   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 620 ], [
 621   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 622 ])
 623
 624 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 625         use_libusb1=yes
 626         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 627         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 628                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 629                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 630         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 631         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 632         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 633                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 634   ], [
 635         use_libusb1=no
 636         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 637 ])
 638
 639 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 640
 641 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 642         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 643                 use_hidapi=yes
 644                 break
 645         ],[
 646                 use_hidapi=no
 647         ])
 648 done
 649
 650 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 651         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 652 ])
 653
 654 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 655
 656 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 657         [use_libjaylink=yes], [use_libjaylink=no])
 658
 659 m4_define([PROCESS_ADAPTERS], [
 660   m4_foreach([adapter], [$1], [
 661         AS_IF([test "x$build_zy1000" = "xyes"], [
 662                 ADAPTER_VAR([adapter])=no
 663         ])
 664         AS_IF([test $2], [
 665                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 666                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 667                 ], [
 668                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 669                 ])
 670         ], [
 671                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 672                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 673                 ])
 674                 ADAPTER_VAR([adapter])=no
 675         ])
 676         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 677   ])
 678 ])
 679
 680 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 681 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 682 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 683 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 684 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 685 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 686 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 687
 688 AS_IF([test "x$build_openjtag" = "xyes"], [
 689   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 690     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 691     build_openjtag=no
 692   ])
 693 ])
 694
 695 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 696   build_bitbang=yes
 697 ])
 698
 699 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
 700         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 701         AM_CONDITIONAL([HLADAPTER], [true])
 702 ], [
 703         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 704         AM_CONDITIONAL([HLADAPTER], [false])
 705 ])
 706 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 707 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 708
 709 AS_IF([test "x$enable_jlink" != "xno"], [
 710   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 711     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 712       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 713                 [--enable-subproject-build])
 714     ], [
 715       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 716     ])
 717   ])
 718 ])
 719
 720 # Presto needs the bitq module
 721 AS_IF([test "x$enable_presto" != "xno"], [
 722   build_bitq=yes
 723 ])
 724
 725 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 726 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 727 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 728 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 729 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 730 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 731 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 732 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 733 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 734 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 735 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 736 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 737 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 738 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 739 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 740 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 741 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 742 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 743 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 744 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 745 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 746 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 747 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 748 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 749 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 750 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 751 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 752 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 753 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 754 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 755 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 756 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 757 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 758
 759 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 760 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 761
 762 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 763 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 764
 765 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 766 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 767 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 768 #define _GNU_SOURCE
 769 #include <unistd.h>
 770 #include <stdlib.h>
 771   ]], [[char **ep = environ;]]
 772   )], [
 773     AC_MSG_RESULT([yes])
 774     has_environ=yes
 775   ], [
 776     AC_MSG_RESULT([no])
 777
 778     # Possibility #2: can environ be found in an available library?
 779     AC_MSG_CHECKING([for extern environ])
 780     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 781     extern char **environ;
 782     ]], [[char **ep = environ;]]
 783       )], [
 784         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 785         has_environ=yes
 786       ], [
 787         has_environ=no
 788       ])
 789     AC_MSG_RESULT([${has_environ}])
 790   ])
 791
 792 AS_IF([test "x${has_environ}" != "xyes" ], [
 793   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 794 ])
 795
 796 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 797
 798 # set default gcc warnings
 799 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 800 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 801   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 802   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 803   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 804   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 805 ])
 806 AS_IF([test "x${gcc_werror}" = "xyes"], [
 807   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 808 ])
 809
 810 # override default gcc cflags
 811 AS_IF([test "x$gcc_warnings" = "xyes"], [
 812   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 813 ])
 814
 815 AC_CONFIG_FILES([
 816   Makefile
 817 ])
 818 AC_OUTPUT
 819
 820 echo
 821 echo
 822 echo OpenOCD configuration summary
 823 echo --------------------------------------------------
 824 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 825         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 826         LIBGPIOD_ADAPTERS,
 827         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
 828         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 829         AS_CASE([$ADAPTER_VAR([adapter])],
 830                 [auto], [
 831                         echo "$s"yes '(auto)'
 832                 ],
 833                 [yes], [
 834                         echo "$s"yes
 835                 ],
 836                 [no], [
 837                         echo "$s"no
 838         ])
 839 ])
 840 echo
 841
 842 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 843   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 844   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 845   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 846   echo
 847 ])
 848
 849 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 850   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 851   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 852   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 853   echo 'Mailing List.'
 854   echo
 855 ])
 856
 857 AS_IF([test "x$build_ioutil" = "xyes"], [
 858   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 859   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 860   echo 'release. If you regularly depend on this functionality, please report to the'
 861   echo 'OpenOCD Mailing List.'
 862   echo
 863 ])