configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG_C
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 AC_PROG_LIBTOOL
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link JTAG Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]]])
 118
 119 m4_define([USB_ADAPTERS],
 120         [[[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 121         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 122         [[aice], [Andes JTAG Programmer], [AICE]]])
 123
 124 m4_define([USB0_ADAPTERS],
 125         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 126         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 127         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 128
 129 m4_define([HIDAPI_ADAPTERS],
 130         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
 131
 132 m4_define([HIDAPI_USB1_ADAPTERS],
 133         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 134
 135 m4_define([LIBFTDI_ADAPTERS],
 136         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 137         [[presto], [ASIX Presto Adapter], [PRESTO]],
 138         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 139
 140 m4_define([LIBJAYLINK_ADAPTERS],
 141         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 142
 143
 144 AC_ARG_ENABLE([doxygen-html],
 145   AS_HELP_STRING([--disable-doxygen-html],
 146     [Disable building Doxygen manual as HTML.]),
 147   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 148 AC_SUBST([doxygen_as_html])
 149 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 150 AC_MSG_RESULT([$doxygen_as_html])
 151
 152 AC_ARG_ENABLE([doxygen-pdf],
 153   AS_HELP_STRING([--enable-doxygen-pdf],
 154     [Enable building Doxygen manual as PDF.]),
 155   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 156 AC_SUBST([doxygen_as_pdf])
 157 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 158 AC_MSG_RESULT([$doxygen_as_pdf])
 159
 160 AC_ARG_ENABLE([gccwarnings],
 161   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 162   [gcc_warnings=$enableval], [gcc_warnings=yes])
 163
 164 AC_ARG_ENABLE([wextra],
 165   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 166   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 167
 168 AC_ARG_ENABLE([werror],
 169   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 170   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 171
 172 # set default verbose options, overridden by following options
 173 debug_jtag_io=no
 174 debug_usb_io=no
 175 debug_usb_comms=no
 176
 177 AC_ARG_ENABLE([verbose],
 178   AS_HELP_STRING([--enable-verbose],
 179       [Enable verbose JTAG I/O messages (for debugging).]),
 180   [
 181   debug_jtag_io=$enableval
 182   debug_usb_io=$enableval
 183   debug_usb_comms=$enableval
 184   ], [])
 185
 186 AC_ARG_ENABLE([verbose_jtag_io],
 187   AS_HELP_STRING([--enable-verbose-jtag-io],
 188       [Enable verbose JTAG I/O messages (for debugging).]),
 189   [debug_jtag_io=$enableval], [])
 190
 191 AC_ARG_ENABLE([verbose_usb_io],
 192   AS_HELP_STRING([--enable-verbose-usb-io],
 193       [Enable verbose USB I/O messages (for debugging)]),
 194   [debug_usb_io=$enableval], [])
 195
 196 AC_ARG_ENABLE([verbose_usb_comms],
 197   AS_HELP_STRING([--enable-verbose-usb-comms],
 198       [Enable verbose USB communication messages (for debugging)]),
 199   [debug_usb_comms=$enableval], [])
 200
 201 AC_MSG_CHECKING([whether to enable verbose JTAG I/O messages]);
 202 AC_MSG_RESULT([$debug_jtag_io])
 203 AS_IF([test "x$debug_jtag_io" = "xyes"], [
 204   AC_DEFINE([_DEBUG_JTAG_IO_],[1], [Print verbose JTAG I/O messages])
 205 ])
 206
 207 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 208 AC_MSG_RESULT([$debug_usb_io])
 209 AS_IF([test "x$debug_usb_io" = "xyes"], [
 210   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 211 ])
 212
 213 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 214 AC_MSG_RESULT([$debug_usb_comms])
 215 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 216   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 217 ])
 218
 219 debug_malloc=no
 220 AC_ARG_ENABLE([malloc_logging],
 221   AS_HELP_STRING([--enable-malloc-logging],
 222       [Include free space in logging messages (requires malloc.h).]),
 223   [debug_malloc=$enableval], [])
 224
 225 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 226 AC_MSG_RESULT([$debug_malloc])
 227 AS_IF([test "x$debug_malloc" = "xyes"], [
 228   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 229 ])
 230
 231 AC_ARG_ENABLE([dummy],
 232   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 233   [build_dummy=$enableval], [build_dummy=no])
 234
 235 m4_define([AC_ARG_ADAPTERS], [
 236   m4_foreach([adapter], [$1],
 237         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 238                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 239                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 240                 [], [ADAPTER_VAR([adapter])=$2])
 241   ])
 242 ])
 243
 244 AC_ARG_ADAPTERS([
 245   USB1_ADAPTERS,
 246   USB_ADAPTERS,
 247   USB0_ADAPTERS,
 248   HIDAPI_ADAPTERS,
 249   HIDAPI_USB1_ADAPTERS,
 250   LIBFTDI_ADAPTERS,
 251   LIBJAYLINK_ADAPTERS
 252   ],[auto])
 253
 254 AC_ARG_ENABLE([parport],
 255   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 256   [build_parport=$enableval], [build_parport=no])
 257
 258 AC_ARG_ENABLE([parport_ppdev],
 259   AS_HELP_STRING([--disable-parport-ppdev],
 260       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 261     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 262
 263 AC_ARG_ENABLE([parport_giveio],
 264     AS_HELP_STRING([--enable-parport-giveio],
 265       [Enable use of giveio for parport (for CygWin only)]),
 266     [parport_use_giveio=$enableval], [parport_use_giveio=])
 267
 268 AC_ARG_ENABLE([jtag_vpi],
 269   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 270   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 271
 272 AC_ARG_ENABLE([amtjtagaccel],
 273   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 274   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 275
 276 AC_ARG_ENABLE([zy1000_master],
 277   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 278   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 279
 280 AC_ARG_ENABLE([zy1000],
 281   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 282   [build_zy1000=$enableval], [build_zy1000=no])
 283
 284 AC_ARG_ENABLE([ioutil],
 285   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 286   [build_ioutil=$enableval], [build_ioutil=no])
 287
 288 AS_CASE(["${host_cpu}"],
 289   [arm*], [
 290     AC_ARG_ENABLE([ep93xx],
 291       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 292       [build_ep93xx=$enableval], [build_ep93xx=no])
 293
 294     AC_ARG_ENABLE([at91rm9200],
 295       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 296       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 297
 298     AC_ARG_ENABLE([bcm2835gpio],
 299       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 300       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 301   ],
 302   [
 303     build_ep93xx=no
 304     build_at91rm9200=no
 305     build_bcm2835gpio=no
 306 ])
 307
 308 AC_ARG_ENABLE([gw16012],
 309   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 310   [build_gw16012=$enableval], [build_gw16012=no])
 311
 312 AC_ARG_ENABLE([oocd_trace],
 313   AS_HELP_STRING([--enable-oocd_trace],
 314   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 315   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 316
 317 AC_ARG_ENABLE([buspirate],
 318   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 319   [build_buspirate=$enableval], [build_buspirate=no])
 320
 321 AC_ARG_ENABLE([sysfsgpio],
 322   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 323   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 324
 325 AS_CASE([$host_os],
 326   [linux*], [],
 327   [
 328     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 329       AC_MSG_ERROR([sysfsgpio is only available on linux])
 330     ])
 331 ])
 332
 333 AC_ARG_ENABLE([minidriver_dummy],
 334   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 335   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 336
 337 AC_ARG_ENABLE([internal-jimtcl],
 338   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 339   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 340
 341 AC_ARG_ENABLE([internal-libjaylink],
 342   AS_HELP_STRING([--disable-internal-libjaylink],
 343   [Disable building internal libjaylink]),
 344   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 345
 346 AC_ARG_ENABLE([target64],
 347   AS_HELP_STRING([--disable-target64], [Disable 64-bit target address]),
 348     [build_target64=$enableval], [build_target64=yes])
 349
 350 build_minidriver=no
 351 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 352 AS_IF([test "x$build_zy1000" = "xyes"], [
 353   AS_IF([test "x$build_minidriver" = "xyes"], [
 354     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 355   ])
 356   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 357       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 358   build_minidriver=yes
 359 ])
 360 AC_MSG_RESULT([$build_zy1000])
 361
 362 AC_ARG_ENABLE([remote-bitbang],
 363   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 364   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 365
 366 AC_MSG_CHECKING([whether to enable dummy minidriver])
 367 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 368   AS_IF([test "x$build_minidriver" = "xyes"], [
 369     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 370   ])
 371   build_minidriver=yes
 372   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 373   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 374       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 375 ])
 376 AC_MSG_RESULT([$build_minidriver_dummy])
 377
 378 AC_MSG_CHECKING([whether standard drivers can be built])
 379 AS_IF([test "x$build_minidriver" = "xyes"], [
 380   AC_MSG_RESULT([no])
 381   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 382   sleep 2
 383 ], [
 384   AC_MSG_RESULT([yes])
 385 ])
 386
 387 AS_CASE(["${host_cpu}"],
 388   [i?86|x86*], [],
 389   [
 390     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 391       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 392     ])
 393     parport_use_ppdev=yes
 394 ])
 395
 396 AS_CASE([$host],
 397   [*-cygwin*], [
 398     is_win32=yes
 399     parport_use_ppdev=no
 400
 401     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 402       [is_mingw=yes],[is_mingw=no])
 403     AS_IF([test "x$is_mingw" = "xyes"], [
 404       AS_IF([test "x$parport_use_giveio" = "xno"], [
 405         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 406       ])
 407       parport_use_giveio=yes
 408       is_cygwin=no
 409     ], [
 410       is_cygwin=yes
 411       # sys/io.h needed under cygwin for parport access
 412       AS_IF([test "x$build_parport" = "xyes"], [
 413         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 414       ])
 415     ])
 416   ],
 417   [*-mingw* | *-msys*], [
 418     is_mingw=yes
 419     is_win32=yes
 420     parport_use_ppdev=no
 421
 422     AS_IF([test "x$parport_use_giveio" = "xno"], [
 423       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 424     ])
 425     parport_use_giveio=yes
 426
 427     AS_IF([test "x$build_buspirate" = "xyes"], [
 428       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 429     ])
 430
 431     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 432   ],
 433   [*darwin*], [
 434     is_darwin=yes
 435
 436     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 437       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 438     ])
 439     parport_use_giveio=no
 440   ],
 441   [
 442     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 443       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 444     ])
 445     parport_use_giveio=no
 446 ])
 447
 448 AS_IF([test "x$is_cygwin" = "xyes"], [
 449     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 450 ], [
 451     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 452 ])
 453
 454 AS_IF([test "x$is_mingw" = "xyes"], [
 455     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 456 ], [
 457     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 458 ])
 459
 460 AS_IF([test "x$is_win32" = "xyes"], [
 461     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 462 ], [
 463     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 464 ])
 465
 466 AS_IF([test "x$is_darwin" = "xyes"], [
 467     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 468 ], [
 469     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 470 ])
 471
 472 AS_IF([test "x$build_parport" = "xyes"], [
 473   build_bitbang=yes
 474   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 475 ], [
 476   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 477 ])
 478
 479 AS_IF([test "x$build_dummy" = "xyes"], [
 480   build_bitbang=yes
 481   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 482 ], [
 483   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 484 ])
 485
 486 AS_IF([test "x$build_ep93xx" = "xyes"], [
 487   build_bitbang=yes
 488   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 489 ], [
 490   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 491 ])
 492
 493 AS_IF([test "x$build_zy1000" = "xyes"], [
 494   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 495 ], [
 496   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 497 ])
 498
 499 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 500   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 501 ], [
 502   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 503 ])
 504
 505 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 506   build_bitbang=yes
 507   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 508 ], [
 509   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 510 ])
 511
 512 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 513   build_bitbang=yes
 514   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 515 ], [
 516   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 517 ])
 518
 519 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 520   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 521 ], [
 522   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 523 ])
 524
 525 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 526   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 527 ], [
 528   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 529 ])
 530
 531 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 532   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 533 ], [
 534   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 535 ])
 536
 537 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 538   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 539 ], [
 540   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 541 ])
 542
 543 AS_IF([test "x$build_gw16012" = "xyes"], [
 544   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 545 ], [
 546   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 547 ])
 548
 549 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 550   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 551 ], [
 552   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 553 ])
 554
 555 AS_IF([test "x$build_buspirate" = "xyes"], [
 556   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 557 ], [
 558   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 559 ])
 560
 561 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 562   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 563     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim --with-ext="eventloop array clock regexp stdlib tclcompat" --without-ext="default"])
 564   ], [
 565     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 566   ])
 567 ])
 568
 569 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 570   build_bitbang=yes
 571   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 572 ], [
 573   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 574 ])
 575
 576 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 577   build_bitbang=yes
 578   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 579 ], [
 580   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 581 ])
 582
 583 AS_IF([test "x$build_target64" = "xyes"], [
 584   AC_DEFINE([BUILD_TARGET64], [1], [1 if you want 64-bit addresses.])
 585 ], [
 586   AC_DEFINE([BUILD_TARGET64], [0], [0 if you don't want 64-bit addresses.])
 587 ])
 588
 589
 590 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 591         use_libusb1=yes
 592         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 593         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 594                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 595                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 596         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 597         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 598         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 599                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 600   ], [
 601         use_libusb1=no
 602         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 603 ])
 604
 605 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 606
 607 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 608         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 609                 use_hidapi=yes
 610                 break
 611         ],[
 612                 use_hidapi=no
 613         ])
 614 done
 615
 616 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 617         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 618 ])
 619
 620 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.1],
 621         [use_libjaylink=yes], [use_libjaylink=no])
 622
 623 m4_define([PROCESS_ADAPTERS], [
 624   m4_foreach([adapter], [$1], [
 625         AS_IF([test $2], [
 626                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 627                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 628                 ], [
 629                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 630                 ])
 631         ], [
 632                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 633                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 634                 ])
 635                 ADAPTER_VAR([adapter])=no
 636         ])
 637         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 638   ])
 639 ])
 640
 641 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 642 PROCESS_ADAPTERS([USB_ADAPTERS], ["x$use_libusb1" = "xyes" -o "x$use_libusb0" = "xyes"], [libusb-1.x or libusb-0.1])
 643 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 644 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 645 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 646 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 647 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_libusb1" = "xyes" -a "x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libusb-1.x or libjaylink-0.1])
 648
 649 AS_IF([test "x$build_openjtag" = "xyes"], [
 650   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 651     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 652     build_openjtag=no
 653   ])
 654 ])
 655
 656 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
 657         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 658 ], [
 659         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 660 ])
 661 AM_CONDITIONAL([HLADAPTER], [test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"])
 662
 663 AS_IF([test "x$enable_jlink" != "xno"], [
 664   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 665     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 666       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 667                 [--enable-subproject-build])
 668     ], [
 669       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 670     ])
 671   ])
 672 ])
 673
 674 # Presto needs the bitq module
 675 AS_IF([test "x$enable_presto" != "xno"], [
 676   build_bitq=yes
 677 ])
 678
 679 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 680 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 681 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 682 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 683 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 684 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 685 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 686 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 687 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 688 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 689 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 690 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 691 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 692 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 693 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 694 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 695 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 696 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 697 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 698 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 699 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 700 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 701 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 702 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 703 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 704 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 705 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 706 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 707 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 708 AM_CONDITIONAL([TARGET64], [test "x$build_target64" = "xyes"])
 709
 710 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 711 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 712
 713 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 714 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 715
 716 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 717 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 718 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 719 #define _GNU_SOURCE
 720 #include <unistd.h>
 721 #include <stdlib.h>
 722   ]], [[char **ep = environ;]]
 723   )], [
 724     AC_MSG_RESULT([yes])
 725     has_environ=yes
 726   ], [
 727     AC_MSG_RESULT([no])
 728
 729     # Possibility #2: can environ be found in an available library?
 730     AC_MSG_CHECKING([for extern environ])
 731     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 732     extern char **environ;
 733     ]], [[char **ep = environ;]]
 734       )], [
 735         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 736         has_environ=yes
 737       ], [
 738         has_environ=no
 739       ])
 740     AC_MSG_RESULT([${has_environ}])
 741   ])
 742
 743 AS_IF([test "x${has_environ}" != "xyes" ], [
 744   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 745 ])
 746
 747 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 748
 749 # set default gcc warnings
 750 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 751 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 752   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 753   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 754   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 755   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 756 ])
 757 AS_IF([test "x${gcc_werror}" = "xyes"], [
 758   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 759 ])
 760
 761 # overide default gcc cflags
 762 AS_IF([test "x$gcc_warnings" = "xyes"], [
 763   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 764 ])
 765
 766 AC_CONFIG_FILES([
 767   Makefile
 768 ])
 769 AC_OUTPUT
 770
 771 echo
 772 echo
 773 echo OpenOCD configuration summary
 774 echo --------------------------------------------------
 775 m4_foreach([adapter], [USB1_ADAPTERS, USB_ADAPTERS, USB0_ADAPTERS,
 776         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 777         LIBJAYLINK_ADAPTERS],
 778         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 779         AS_CASE([$ADAPTER_VAR([adapter])],
 780                 [auto], [
 781                         echo "$s"yes '(auto)'
 782                 ],
 783                 [yes], [
 784                         echo "$s"yes
 785                 ],
 786                 [no], [
 787                         echo "$s"no
 788         ])
 789 ])
 790 echo
 791
 792 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 793   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 794   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 795   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 796   echo
 797 ])
 798
 799 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 800   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 801   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 802   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 803   echo 'Mailing List.'
 804   echo
 805 ])
 806
 807 AS_IF([test "x$build_ioutil" = "xyes"], [
 808   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 809   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 810   echo 'release. If you regularly depend on this functionality, please report to the'
 811   echo 'OpenOCD Mailing List.'
 812   echo
 813 ])