configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG_C
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 AC_PROG_LIBTOOL
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 119         [[xds110], [TI XDS110 Debug Probe], [XDS110]]])
 120
 121 m4_define([USB_ADAPTERS],
 122         [[[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 123         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 124         [[aice], [Andes JTAG Programmer], [AICE]]])
 125
 126 m4_define([USB0_ADAPTERS],
 127         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 128         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 129         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 130
 131 m4_define([HIDAPI_ADAPTERS],
 132         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
 133
 134 m4_define([HIDAPI_USB1_ADAPTERS],
 135         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 136
 137 m4_define([LIBFTDI_ADAPTERS],
 138         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 139         [[presto], [ASIX Presto Adapter], [PRESTO]],
 140         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 141
 142 m4_define([LIBJAYLINK_ADAPTERS],
 143         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 144
 145
 146 AC_ARG_ENABLE([doxygen-html],
 147   AS_HELP_STRING([--disable-doxygen-html],
 148     [Disable building Doxygen manual as HTML.]),
 149   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 150 AC_SUBST([doxygen_as_html])
 151 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 152 AC_MSG_RESULT([$doxygen_as_html])
 153
 154 AC_ARG_ENABLE([doxygen-pdf],
 155   AS_HELP_STRING([--enable-doxygen-pdf],
 156     [Enable building Doxygen manual as PDF.]),
 157   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 158 AC_SUBST([doxygen_as_pdf])
 159 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 160 AC_MSG_RESULT([$doxygen_as_pdf])
 161
 162 AC_ARG_ENABLE([gccwarnings],
 163   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 164   [gcc_warnings=$enableval], [gcc_warnings=yes])
 165
 166 AC_ARG_ENABLE([wextra],
 167   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 168   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 169
 170 AC_ARG_ENABLE([werror],
 171   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 172   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 173
 174 # set default verbose options, overridden by following options
 175 debug_usb_io=no
 176 debug_usb_comms=no
 177
 178 AC_ARG_ENABLE([verbose],
 179   AS_HELP_STRING([--enable-verbose],
 180       [Enable verbose JTAG I/O messages (for debugging).]),
 181   [
 182   debug_usb_io=$enableval
 183   debug_usb_comms=$enableval
 184   ], [])
 185
 186 AC_ARG_ENABLE([verbose_usb_io],
 187   AS_HELP_STRING([--enable-verbose-usb-io],
 188       [Enable verbose USB I/O messages (for debugging)]),
 189   [debug_usb_io=$enableval], [])
 190
 191 AC_ARG_ENABLE([verbose_usb_comms],
 192   AS_HELP_STRING([--enable-verbose-usb-comms],
 193       [Enable verbose USB communication messages (for debugging)]),
 194   [debug_usb_comms=$enableval], [])
 195
 196 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 197 AC_MSG_RESULT([$debug_usb_io])
 198 AS_IF([test "x$debug_usb_io" = "xyes"], [
 199   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 200 ])
 201
 202 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 203 AC_MSG_RESULT([$debug_usb_comms])
 204 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 205   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 206 ])
 207
 208 debug_malloc=no
 209 AC_ARG_ENABLE([malloc_logging],
 210   AS_HELP_STRING([--enable-malloc-logging],
 211       [Include free space in logging messages (requires malloc.h).]),
 212   [debug_malloc=$enableval], [])
 213
 214 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 215 AC_MSG_RESULT([$debug_malloc])
 216 AS_IF([test "x$debug_malloc" = "xyes"], [
 217   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 218 ])
 219
 220 AC_ARG_ENABLE([dummy],
 221   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 222   [build_dummy=$enableval], [build_dummy=no])
 223
 224 m4_define([AC_ARG_ADAPTERS], [
 225   m4_foreach([adapter], [$1],
 226         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 227                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 228                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 229                 [], [ADAPTER_VAR([adapter])=$2])
 230   ])
 231 ])
 232
 233 AC_ARG_ADAPTERS([
 234   USB1_ADAPTERS,
 235   USB_ADAPTERS,
 236   USB0_ADAPTERS,
 237   HIDAPI_ADAPTERS,
 238   HIDAPI_USB1_ADAPTERS,
 239   LIBFTDI_ADAPTERS,
 240   LIBJAYLINK_ADAPTERS
 241   ],[auto])
 242
 243 AC_ARG_ENABLE([parport],
 244   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 245   [build_parport=$enableval], [build_parport=no])
 246
 247 AC_ARG_ENABLE([parport_ppdev],
 248   AS_HELP_STRING([--disable-parport-ppdev],
 249       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 250     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 251
 252 AC_ARG_ENABLE([parport_giveio],
 253     AS_HELP_STRING([--enable-parport-giveio],
 254       [Enable use of giveio for parport (for CygWin only)]),
 255     [parport_use_giveio=$enableval], [parport_use_giveio=])
 256
 257 AC_ARG_ENABLE([jtag_vpi],
 258   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 259   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 260
 261 AC_ARG_ENABLE([amtjtagaccel],
 262   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 263   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 264
 265 AC_ARG_ENABLE([zy1000_master],
 266   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 267   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 268
 269 AC_ARG_ENABLE([zy1000],
 270   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 271   [build_zy1000=$enableval], [build_zy1000=no])
 272
 273 AC_ARG_ENABLE([ioutil],
 274   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 275   [build_ioutil=$enableval], [build_ioutil=no])
 276
 277 AS_CASE(["${host_cpu}"],
 278   [arm*], [
 279     AC_ARG_ENABLE([ep93xx],
 280       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 281       [build_ep93xx=$enableval], [build_ep93xx=no])
 282
 283     AC_ARG_ENABLE([at91rm9200],
 284       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 285       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 286
 287     AC_ARG_ENABLE([bcm2835gpio],
 288       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 289       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 290     AC_ARG_ENABLE([imx_gpio],
 291       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 292       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 293   ],
 294   [
 295     build_ep93xx=no
 296     build_at91rm9200=no
 297     build_bcm2835gpio=no
 298     build_imx_gpio=no
 299 ])
 300
 301 AC_ARG_ENABLE([gw16012],
 302   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 303   [build_gw16012=$enableval], [build_gw16012=no])
 304
 305 AC_ARG_ENABLE([oocd_trace],
 306   AS_HELP_STRING([--enable-oocd_trace],
 307   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 308   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 309
 310 AC_ARG_ENABLE([buspirate],
 311   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 312   [build_buspirate=$enableval], [build_buspirate=no])
 313
 314 AC_ARG_ENABLE([sysfsgpio],
 315   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 316   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 317
 318 AS_CASE([$host_os],
 319   [linux*], [],
 320   [
 321     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 322       AC_MSG_ERROR([sysfsgpio is only available on linux])
 323     ])
 324 ])
 325
 326 AC_ARG_ENABLE([minidriver_dummy],
 327   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 328   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 329
 330 AC_ARG_ENABLE([internal-jimtcl],
 331   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 332   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 333
 334 AC_ARG_ENABLE([internal-libjaylink],
 335   AS_HELP_STRING([--disable-internal-libjaylink],
 336   [Disable building internal libjaylink]),
 337   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 338
 339 AC_ARG_ENABLE([target64],
 340   AS_HELP_STRING([--disable-target64], [Disable 64-bit target address]),
 341     [build_target64=$enableval], [build_target64=yes])
 342
 343 build_minidriver=no
 344 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 345 AS_IF([test "x$build_zy1000" = "xyes"], [
 346   AS_IF([test "x$build_minidriver" = "xyes"], [
 347     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 348   ])
 349   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 350       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 351   build_minidriver=yes
 352 ])
 353 AC_MSG_RESULT([$build_zy1000])
 354
 355 AC_ARG_ENABLE([remote-bitbang],
 356   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 357   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 358
 359 AC_MSG_CHECKING([whether to enable dummy minidriver])
 360 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 361   AS_IF([test "x$build_minidriver" = "xyes"], [
 362     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 363   ])
 364   build_minidriver=yes
 365   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 366   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 367       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 368 ])
 369 AC_MSG_RESULT([$build_minidriver_dummy])
 370
 371 AC_MSG_CHECKING([whether standard drivers can be built])
 372 AS_IF([test "x$build_minidriver" = "xyes"], [
 373   AC_MSG_RESULT([no])
 374   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 375   sleep 2
 376 ], [
 377   AC_MSG_RESULT([yes])
 378 ])
 379
 380 AS_CASE(["${host_cpu}"],
 381   [i?86|x86*], [],
 382   [
 383     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 384       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 385     ])
 386     parport_use_ppdev=yes
 387 ])
 388
 389 AS_CASE([$host],
 390   [*-cygwin*], [
 391     is_win32=yes
 392     parport_use_ppdev=no
 393
 394     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 395       [is_mingw=yes],[is_mingw=no])
 396     AS_IF([test "x$is_mingw" = "xyes"], [
 397       AS_IF([test "x$parport_use_giveio" = "xno"], [
 398         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 399       ])
 400       parport_use_giveio=yes
 401       is_cygwin=no
 402     ], [
 403       is_cygwin=yes
 404       # sys/io.h needed under cygwin for parport access
 405       AS_IF([test "x$build_parport" = "xyes"], [
 406         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 407       ])
 408     ])
 409   ],
 410   [*-mingw* | *-msys*], [
 411     is_mingw=yes
 412     is_win32=yes
 413     parport_use_ppdev=no
 414
 415     AS_IF([test "x$parport_use_giveio" = "xno"], [
 416       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 417     ])
 418     parport_use_giveio=yes
 419
 420     AS_IF([test "x$build_buspirate" = "xyes"], [
 421       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 422     ])
 423
 424     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 425   ],
 426   [*darwin*], [
 427     is_darwin=yes
 428
 429     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 430       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 431     ])
 432     parport_use_giveio=no
 433   ],
 434   [
 435     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 436       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 437     ])
 438     parport_use_giveio=no
 439 ])
 440
 441 AS_IF([test "x$is_cygwin" = "xyes"], [
 442     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 443 ], [
 444     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 445 ])
 446
 447 AS_IF([test "x$is_mingw" = "xyes"], [
 448     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 449 ], [
 450     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 451 ])
 452
 453 AS_IF([test "x$is_win32" = "xyes"], [
 454     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 455 ], [
 456     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 457 ])
 458
 459 AS_IF([test "x$is_darwin" = "xyes"], [
 460     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 461 ], [
 462     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 463 ])
 464
 465 AS_IF([test "x$build_parport" = "xyes"], [
 466   build_bitbang=yes
 467   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 468 ], [
 469   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 470 ])
 471
 472 AS_IF([test "x$build_dummy" = "xyes"], [
 473   build_bitbang=yes
 474   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 475 ], [
 476   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 477 ])
 478
 479 AS_IF([test "x$build_ep93xx" = "xyes"], [
 480   build_bitbang=yes
 481   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 482 ], [
 483   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 484 ])
 485
 486 AS_IF([test "x$build_zy1000" = "xyes"], [
 487   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 488 ], [
 489   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 490 ])
 491
 492 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 493   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 494 ], [
 495   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 496 ])
 497
 498 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 499   build_bitbang=yes
 500   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 501 ], [
 502   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 503 ])
 504
 505 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 506   build_bitbang=yes
 507   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 508 ], [
 509   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 510 ])
 511
 512 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 513   build_bitbang=yes
 514   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 515 ], [
 516   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 517 ])
 518
 519 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 520   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 521 ], [
 522   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 523 ])
 524
 525 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 526   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 527 ], [
 528   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 529 ])
 530
 531 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 532   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 533 ], [
 534   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 535 ])
 536
 537 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 538   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 539 ], [
 540   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 541 ])
 542
 543 AS_IF([test "x$build_gw16012" = "xyes"], [
 544   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 545 ], [
 546   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 547 ])
 548
 549 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 550   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 551 ], [
 552   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 553 ])
 554
 555 AS_IF([test "x$build_buspirate" = "xyes"], [
 556   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 557 ], [
 558   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 559 ])
 560
 561 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 562   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 563     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 564   ], [
 565     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 566   ])
 567 ])
 568
 569 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 570   build_bitbang=yes
 571   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 572 ], [
 573   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 574 ])
 575
 576 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 577   build_bitbang=yes
 578   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 579 ], [
 580   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 581 ])
 582
 583 AS_IF([test "x$build_target64" = "xyes"], [
 584   AC_DEFINE([BUILD_TARGET64], [1], [1 if you want 64-bit addresses.])
 585 ], [
 586   AC_DEFINE([BUILD_TARGET64], [0], [0 if you don't want 64-bit addresses.])
 587 ])
 588
 589
 590 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 591         use_libusb1=yes
 592         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 593         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 594                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 595                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 596         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 597         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 598         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 599                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 600   ], [
 601         use_libusb1=no
 602         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 603 ])
 604
 605 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 606
 607 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 608         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 609                 use_hidapi=yes
 610                 break
 611         ],[
 612                 use_hidapi=no
 613         ])
 614 done
 615
 616 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 617         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 618 ])
 619
 620 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 621         [use_libjaylink=yes], [use_libjaylink=no])
 622
 623 m4_define([PROCESS_ADAPTERS], [
 624   m4_foreach([adapter], [$1], [
 625         AS_IF([test "x$build_zy1000" = "xyes"], [
 626                 ADAPTER_VAR([adapter])=no
 627         ])
 628         AS_IF([test $2], [
 629                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 630                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 631                 ], [
 632                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 633                 ])
 634         ], [
 635                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 636                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 637                 ])
 638                 ADAPTER_VAR([adapter])=no
 639         ])
 640         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 641   ])
 642 ])
 643
 644 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 645 PROCESS_ADAPTERS([USB_ADAPTERS], ["x$use_libusb1" = "xyes" -o "x$use_libusb0" = "xyes"], [libusb-1.x or libusb-0.1])
 646 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 647 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 648 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 649 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 650 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 651
 652 AS_IF([test "x$build_openjtag" = "xyes"], [
 653   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 654     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 655     build_openjtag=no
 656   ])
 657 ])
 658
 659 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
 660         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 661 ], [
 662         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 663 ])
 664 AM_CONDITIONAL([HLADAPTER], [test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"])
 665
 666 AS_IF([test "x$enable_jlink" != "xno"], [
 667   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 668     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 669       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 670                 [--enable-subproject-build])
 671     ], [
 672       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 673     ])
 674   ])
 675 ])
 676
 677 # Presto needs the bitq module
 678 AS_IF([test "x$enable_presto" != "xno"], [
 679   build_bitq=yes
 680 ])
 681
 682 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 683 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 684 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 685 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 686 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 687 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 688 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 689 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 690 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 691 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 692 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 693 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 694 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 695 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 696 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 697 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 698 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 699 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 700 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 701 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 702 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 703 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 704 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 705 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 706 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 707 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 708 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 709 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 710 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 711 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 712 AM_CONDITIONAL([TARGET64], [test "x$build_target64" = "xyes"])
 713
 714 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 715 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 716
 717 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 718 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 719
 720 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 721 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 722 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 723 #define _GNU_SOURCE
 724 #include <unistd.h>
 725 #include <stdlib.h>
 726   ]], [[char **ep = environ;]]
 727   )], [
 728     AC_MSG_RESULT([yes])
 729     has_environ=yes
 730   ], [
 731     AC_MSG_RESULT([no])
 732
 733     # Possibility #2: can environ be found in an available library?
 734     AC_MSG_CHECKING([for extern environ])
 735     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 736     extern char **environ;
 737     ]], [[char **ep = environ;]]
 738       )], [
 739         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 740         has_environ=yes
 741       ], [
 742         has_environ=no
 743       ])
 744     AC_MSG_RESULT([${has_environ}])
 745   ])
 746
 747 AS_IF([test "x${has_environ}" != "xyes" ], [
 748   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 749 ])
 750
 751 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 752
 753 # set default gcc warnings
 754 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 755 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 756   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 757   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 758   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 759   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 760 ])
 761 AS_IF([test "x${gcc_werror}" = "xyes"], [
 762   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 763 ])
 764
 765 # override default gcc cflags
 766 AS_IF([test "x$gcc_warnings" = "xyes"], [
 767   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 768 ])
 769
 770 AC_CONFIG_FILES([
 771   Makefile
 772 ])
 773 AC_OUTPUT
 774
 775 echo
 776 echo
 777 echo OpenOCD configuration summary
 778 echo --------------------------------------------------
 779 m4_foreach([adapter], [USB1_ADAPTERS, USB_ADAPTERS, USB0_ADAPTERS,
 780         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 781         LIBJAYLINK_ADAPTERS],
 782         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 783         AS_CASE([$ADAPTER_VAR([adapter])],
 784                 [auto], [
 785                         echo "$s"yes '(auto)'
 786                 ],
 787                 [yes], [
 788                         echo "$s"yes
 789                 ],
 790                 [no], [
 791                         echo "$s"no
 792         ])
 793 ])
 794 echo
 795
 796 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 797   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 798   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 799   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 800   echo
 801 ])
 802
 803 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 804   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 805   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 806   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 807   echo 'Mailing List.'
 808   echo
 809 ])
 810
 811 AS_IF([test "x$build_ioutil" = "xyes"], [
 812   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 813   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 814   echo 'release. If you regularly depend on this functionality, please report to the'
 815   echo 'OpenOCD Mailing List.'
 816   echo
 817 ])