configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG([C])
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 LT_INIT
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 119         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 120         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 121         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 122         [[aice], [Andes JTAG Programmer], [AICE]]])
 123
 124 m4_define([USB0_ADAPTERS],
 125         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 126         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 127         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 128
 129 m4_define([HIDAPI_ADAPTERS],
 130         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]],
 131         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 132
 133 m4_define([HIDAPI_USB1_ADAPTERS],
 134         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 135
 136 m4_define([LIBFTDI_ADAPTERS],
 137         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 138         [[presto], [ASIX Presto Adapter], [PRESTO]],
 139         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 140
 141 m4_define([LIBGPIOD_ADAPTERS],
 142         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 143
 144 m4_define([LIBJAYLINK_ADAPTERS],
 145         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 146
 147 m4_define([PCIE_ADAPTERS],
 148         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 149
 150
 151 AC_ARG_ENABLE([doxygen-html],
 152   AS_HELP_STRING([--disable-doxygen-html],
 153     [Disable building Doxygen manual as HTML.]),
 154   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 155 AC_SUBST([doxygen_as_html])
 156 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 157 AC_MSG_RESULT([$doxygen_as_html])
 158
 159 AC_ARG_ENABLE([doxygen-pdf],
 160   AS_HELP_STRING([--enable-doxygen-pdf],
 161     [Enable building Doxygen manual as PDF.]),
 162   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 163 AC_SUBST([doxygen_as_pdf])
 164 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 165 AC_MSG_RESULT([$doxygen_as_pdf])
 166
 167 AC_ARG_ENABLE([gccwarnings],
 168   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 169   [gcc_warnings=$enableval], [gcc_warnings=yes])
 170
 171 AC_ARG_ENABLE([wextra],
 172   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 173   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 174
 175 AC_ARG_ENABLE([werror],
 176   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 177   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 178
 179 # set default verbose options, overridden by following options
 180 debug_usb_io=no
 181 debug_usb_comms=no
 182
 183 AC_ARG_ENABLE([verbose],
 184   AS_HELP_STRING([--enable-verbose],
 185       [Enable verbose JTAG I/O messages (for debugging).]),
 186   [
 187   debug_usb_io=$enableval
 188   debug_usb_comms=$enableval
 189   ], [])
 190
 191 AC_ARG_ENABLE([verbose_usb_io],
 192   AS_HELP_STRING([--enable-verbose-usb-io],
 193       [Enable verbose USB I/O messages (for debugging)]),
 194   [debug_usb_io=$enableval], [])
 195
 196 AC_ARG_ENABLE([verbose_usb_comms],
 197   AS_HELP_STRING([--enable-verbose-usb-comms],
 198       [Enable verbose USB communication messages (for debugging)]),
 199   [debug_usb_comms=$enableval], [])
 200
 201 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 202 AC_MSG_RESULT([$debug_usb_io])
 203 AS_IF([test "x$debug_usb_io" = "xyes"], [
 204   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 205 ])
 206
 207 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 208 AC_MSG_RESULT([$debug_usb_comms])
 209 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 210   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 211 ])
 212
 213 debug_malloc=no
 214 AC_ARG_ENABLE([malloc_logging],
 215   AS_HELP_STRING([--enable-malloc-logging],
 216       [Include free space in logging messages (requires malloc.h).]),
 217   [debug_malloc=$enableval], [])
 218
 219 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 220 AC_MSG_RESULT([$debug_malloc])
 221 AS_IF([test "x$debug_malloc" = "xyes"], [
 222   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 223 ])
 224
 225 AC_ARG_ENABLE([dummy],
 226   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 227   [build_dummy=$enableval], [build_dummy=no])
 228
 229 AC_ARG_ENABLE([rshim],
 230   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 231   [build_rshim=$enableval], [build_rshim=no])
 232
 233 m4_define([AC_ARG_ADAPTERS], [
 234   m4_foreach([adapter], [$1],
 235         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 236                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 237                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 238                 [], [ADAPTER_VAR([adapter])=$2])
 239   ])
 240 ])
 241
 242 AC_ARG_ADAPTERS([
 243   USB1_ADAPTERS,
 244   USB0_ADAPTERS,
 245   HIDAPI_ADAPTERS,
 246   HIDAPI_USB1_ADAPTERS,
 247   LIBFTDI_ADAPTERS,
 248   LIBGPIOD_ADAPTERS,
 249   LIBJAYLINK_ADAPTERS
 250   ],[auto])
 251
 252 AC_ARG_ENABLE([parport],
 253   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 254   [build_parport=$enableval], [build_parport=no])
 255
 256 AC_ARG_ENABLE([parport_ppdev],
 257   AS_HELP_STRING([--disable-parport-ppdev],
 258       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 259     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 260
 261 AC_ARG_ENABLE([parport_giveio],
 262     AS_HELP_STRING([--enable-parport-giveio],
 263       [Enable use of giveio for parport (for CygWin only)]),
 264     [parport_use_giveio=$enableval], [parport_use_giveio=])
 265
 266 AC_ARG_ENABLE([jtag_vpi],
 267   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 268   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 269
 270 AC_ARG_ENABLE([jtag_dpi],
 271   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 272   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 273
 274 AC_ARG_ENABLE([amtjtagaccel],
 275   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 276   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 277
 278 AC_ARG_ENABLE([zy1000_master],
 279   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 280   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 281
 282 AC_ARG_ENABLE([zy1000],
 283   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 284   [build_zy1000=$enableval], [build_zy1000=no])
 285
 286 AC_ARG_ENABLE([ioutil],
 287   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 288   [build_ioutil=$enableval], [build_ioutil=no])
 289
 290 AS_CASE(["${host_cpu}"],
 291   [arm*|aarch64], [
 292     AC_ARG_ENABLE([bcm2835gpio],
 293       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 294       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 295     AC_ARG_ENABLE([imx_gpio],
 296       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 297       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 298   ],
 299   [
 300     build_bcm2835gpio=no
 301     build_imx_gpio=no
 302 ])
 303
 304 AS_CASE(["${host_cpu}"],
 305   [arm*], [
 306     AC_ARG_ENABLE([ep93xx],
 307       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 308       [build_ep93xx=$enableval], [build_ep93xx=no])
 309
 310     AC_ARG_ENABLE([at91rm9200],
 311       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 312       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 313   ],
 314   [
 315     build_ep93xx=no
 316     build_at91rm9200=no
 317 ])
 318
 319 AC_ARG_ENABLE([gw16012],
 320   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 321   [build_gw16012=$enableval], [build_gw16012=no])
 322
 323 AC_ARG_ENABLE([oocd_trace],
 324   AS_HELP_STRING([--enable-oocd_trace],
 325   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 326   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 327
 328 AC_ARG_ENABLE([buspirate],
 329   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 330   [build_buspirate=$enableval], [build_buspirate=no])
 331
 332 AC_ARG_ENABLE([sysfsgpio],
 333   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 334   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 335
 336 AC_ARG_ENABLE([xlnx_pcie_xvc],
 337   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 338   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 339
 340 AS_CASE([$host_os],
 341   [linux*], [],
 342   [
 343     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 344       AC_MSG_ERROR([sysfsgpio is only available on linux])
 345     ])
 346
 347     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 348       AC_MSG_ERROR([linuxgpiod is only available on linux])
 349     ])
 350
 351     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 352       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 353     ])
 354
 355     AS_CASE([$host_os], [freebsd*], [],
 356     [
 357       AS_IF([test "x$build_rshim" = "xyes"], [
 358         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 359       ])
 360     ])
 361 ])
 362
 363 AC_ARG_ENABLE([minidriver_dummy],
 364   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 365   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 366
 367 AC_ARG_ENABLE([internal-jimtcl],
 368   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 369   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 370
 371 AC_ARG_ENABLE([internal-libjaylink],
 372   AS_HELP_STRING([--disable-internal-libjaylink],
 373   [Disable building internal libjaylink]),
 374   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 375
 376 build_minidriver=no
 377 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 378 AS_IF([test "x$build_zy1000" = "xyes"], [
 379   AS_IF([test "x$build_minidriver" = "xyes"], [
 380     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 381   ])
 382   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 383       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 384   build_minidriver=yes
 385 ])
 386 AC_MSG_RESULT([$build_zy1000])
 387
 388 AC_ARG_ENABLE([remote-bitbang],
 389   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 390   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 391
 392 AC_MSG_CHECKING([whether to enable dummy minidriver])
 393 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 394   AS_IF([test "x$build_minidriver" = "xyes"], [
 395     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 396   ])
 397   build_minidriver=yes
 398   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 399   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 400       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 401 ])
 402 AC_MSG_RESULT([$build_minidriver_dummy])
 403
 404 AC_MSG_CHECKING([whether standard drivers can be built])
 405 AS_IF([test "x$build_minidriver" = "xyes"], [
 406   AC_MSG_RESULT([no])
 407   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 408   sleep 2
 409 ], [
 410   AC_MSG_RESULT([yes])
 411 ])
 412
 413 AS_CASE(["${host_cpu}"],
 414   [i?86|x86*], [],
 415   [
 416     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 417       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 418     ])
 419     parport_use_ppdev=yes
 420 ])
 421
 422 AS_CASE([$host],
 423   [*-cygwin*], [
 424     is_win32=yes
 425     parport_use_ppdev=no
 426
 427     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 428       [is_mingw=yes],[is_mingw=no])
 429     AS_IF([test "x$is_mingw" = "xyes"], [
 430       AS_IF([test "x$parport_use_giveio" = "xno"], [
 431         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 432       ])
 433       parport_use_giveio=yes
 434       is_cygwin=no
 435     ], [
 436       is_cygwin=yes
 437       # sys/io.h needed under cygwin for parport access
 438       AS_IF([test "x$build_parport" = "xyes"], [
 439         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 440       ])
 441     ])
 442   ],
 443   [*-mingw* | *-msys*], [
 444     is_mingw=yes
 445     is_win32=yes
 446     parport_use_ppdev=no
 447
 448     AS_IF([test "x$parport_use_giveio" = "xno"], [
 449       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 450     ])
 451     parport_use_giveio=yes
 452
 453     AS_IF([test "x$build_buspirate" = "xyes"], [
 454       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 455     ])
 456
 457     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 458   ],
 459   [*darwin*], [
 460     is_darwin=yes
 461
 462     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 463       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 464     ])
 465     parport_use_giveio=no
 466   ],
 467   [
 468     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 469       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 470     ])
 471     parport_use_giveio=no
 472 ])
 473
 474 AS_IF([test "x$is_cygwin" = "xyes"], [
 475     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 476 ], [
 477     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 478 ])
 479
 480 AS_IF([test "x$is_mingw" = "xyes"], [
 481     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 482 ], [
 483     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 484 ])
 485
 486 AS_IF([test "x$is_win32" = "xyes"], [
 487     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 488 ], [
 489     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 490 ])
 491
 492 AS_IF([test "x$is_darwin" = "xyes"], [
 493     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 494 ], [
 495     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 496 ])
 497
 498 AS_IF([test "x$build_parport" = "xyes"], [
 499   build_bitbang=yes
 500   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 501 ], [
 502   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 503 ])
 504
 505 AS_IF([test "x$build_rshim" = "xyes"], [
 506   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 507 ], [
 508   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 509 ])
 510
 511 AS_IF([test "x$build_dummy" = "xyes"], [
 512   build_bitbang=yes
 513   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 514 ], [
 515   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 516 ])
 517
 518 AS_IF([test "x$build_ep93xx" = "xyes"], [
 519   build_bitbang=yes
 520   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 521 ], [
 522   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 523 ])
 524
 525 AS_IF([test "x$build_zy1000" = "xyes"], [
 526   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 527 ], [
 528   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 529 ])
 530
 531 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 532   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 533 ], [
 534   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 535 ])
 536
 537 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 538   build_bitbang=yes
 539   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 540 ], [
 541   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 542 ])
 543
 544 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 545   build_bitbang=yes
 546   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 547 ], [
 548   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 549 ])
 550
 551 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 552   build_bitbang=yes
 553   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 554 ], [
 555   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 556 ])
 557
 558 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 559   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 560 ], [
 561   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 562 ])
 563
 564 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 565   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 566 ], [
 567   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 568 ])
 569
 570 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 571   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 572 ], [
 573   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 574 ])
 575
 576 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 577   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 578 ], [
 579   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 580 ])
 581
 582
 583 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 584   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 585 ], [
 586   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 587 ])
 588
 589 AS_IF([test "x$build_gw16012" = "xyes"], [
 590   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 591 ], [
 592   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 593 ])
 594
 595 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 596   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 597 ], [
 598   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 599 ])
 600
 601 AS_IF([test "x$build_buspirate" = "xyes"], [
 602   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 603 ], [
 604   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 605 ])
 606
 607 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 608   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 609     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 610   ], [
 611     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 612   ])
 613 ])
 614
 615 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 616   build_bitbang=yes
 617   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 618 ], [
 619   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 620 ])
 621
 622 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 623   build_bitbang=yes
 624   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 625 ], [
 626   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 627 ])
 628
 629 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 630   build_xlnx_pcie_xvc=yes
 631   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 632 ], [
 633   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 634 ])
 635
 636 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 637         use_libusb1=yes
 638         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 639         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 640                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 641                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 642         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 643         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 644         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 645                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 646   ], [
 647         use_libusb1=no
 648         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 649 ])
 650
 651 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 652
 653 PKG_CHECK_MODULES([CAPSTONE], [capstone], [have_capstone=yes],
 654         [have_capstone=no])
 655
 656 AS_IF([test "x$have_capstone" = "xyes"], [
 657   AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have captone disassembly framework.])
 658 ], [
 659   AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have captone disassembly framework.])
 660 ])
 661
 662 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 663         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 664                 use_hidapi=yes
 665                 break
 666         ],[
 667                 use_hidapi=no
 668         ])
 669 done
 670
 671 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 672         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 673 ])
 674
 675 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 676
 677 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 678         [use_libjaylink=yes], [use_libjaylink=no])
 679
 680 m4_define([PROCESS_ADAPTERS], [
 681   m4_foreach([adapter], [$1], [
 682         AS_IF([test "x$build_zy1000" = "xyes"], [
 683                 ADAPTER_VAR([adapter])=no
 684         ])
 685         AS_IF([test $2], [
 686                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 687                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 688                 ], [
 689                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 690                 ])
 691         ], [
 692                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 693                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 694                 ])
 695                 ADAPTER_VAR([adapter])=no
 696         ])
 697         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 698   ])
 699 ])
 700
 701 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 702 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 703 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 704 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 705 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 706 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 707 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 708
 709 AS_IF([test "x$build_openjtag" = "xyes"], [
 710   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 711     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 712     build_openjtag=no
 713   ])
 714 ])
 715
 716 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 717   build_bitbang=yes
 718 ])
 719
 720 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 721         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 722         AM_CONDITIONAL([HLADAPTER], [true])
 723 ], [
 724         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 725         AM_CONDITIONAL([HLADAPTER], [false])
 726 ])
 727 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 728 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 729 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 730
 731 AS_IF([test "x$enable_jlink" != "xno"], [
 732   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 733     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 734       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 735                 [--enable-subproject-build])
 736     ], [
 737       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 738     ])
 739   ])
 740 ])
 741
 742 # Presto needs the bitq module
 743 AS_IF([test "x$enable_presto" != "xno"], [
 744   build_bitq=yes
 745 ])
 746
 747 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 748 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 749 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 750 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 751 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 752 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 753 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 754 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 755 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 756 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 757 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 758 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 759 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 760 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
 761 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 762 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 763 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 764 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 765 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 766 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 767 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 768 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 769 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 770 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 771 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 772 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 773 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 774 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 775 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 776 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 777 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 778 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 779 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 780 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 781 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$have_capstone" = "xyes"])
 782
 783 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 784 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 785
 786 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 787 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 788
 789 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 790 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 791 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 792 #define _GNU_SOURCE
 793 #include <unistd.h>
 794 #include <stdlib.h>
 795   ]], [[char **ep = environ;]]
 796   )], [
 797     AC_MSG_RESULT([yes])
 798     has_environ=yes
 799   ], [
 800     AC_MSG_RESULT([no])
 801
 802     # Possibility #2: can environ be found in an available library?
 803     AC_MSG_CHECKING([for extern environ])
 804     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 805     extern char **environ;
 806     ]], [[char **ep = environ;]]
 807       )], [
 808         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 809         has_environ=yes
 810       ], [
 811         has_environ=no
 812       ])
 813     AC_MSG_RESULT([${has_environ}])
 814   ])
 815
 816 AS_IF([test "x${has_environ}" != "xyes" ], [
 817   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 818 ])
 819
 820 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 821
 822 # set default gcc warnings
 823 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 824 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 825   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 826   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 827   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 828   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 829 ])
 830 AS_IF([test "x${gcc_werror}" = "xyes"], [
 831   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 832 ])
 833
 834 # override default gcc cflags
 835 AS_IF([test "x$gcc_warnings" = "xyes"], [
 836   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 837 ])
 838
 839 AC_CONFIG_FILES([
 840   Makefile
 841 ])
 842 AC_OUTPUT
 843
 844 echo
 845 echo
 846 echo OpenOCD configuration summary
 847 echo --------------------------------------------------
 848 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 849         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 850         LIBGPIOD_ADAPTERS,
 851         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
 852         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 853         AS_CASE([$ADAPTER_VAR([adapter])],
 854                 [auto], [
 855                         echo "$s"yes '(auto)'
 856                 ],
 857                 [yes], [
 858                         echo "$s"yes
 859                 ],
 860                 [no], [
 861                         echo "$s"no
 862         ])
 863 ])
 864 echo
 865
 866 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 867   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 868   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 869   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 870   echo
 871 ])
 872
 873 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 874   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 875   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 876   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 877   echo 'Mailing List.'
 878   echo
 879 ])
 880
 881 AS_IF([test "x$build_ioutil" = "xyes"], [
 882   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 883   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 884   echo 'release. If you regularly depend on this functionality, please report to the'
 885   echo 'OpenOCD Mailing List.'
 886   echo
 887 ])