312fda8b23ed73add98c3f93c9972373b408d340
[openocd.git] / configure.ac
1 AC_PREREQ(2.64)
2 AC_INIT([openocd], [0.10.0+dev],
3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
4 AC_CONFIG_SRCDIR([src/openocd.c])
5
6 m4_include([config_subdir.m4])dnl
7
8 # check for makeinfo before calling AM_INIT_AUTOMAKE
9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
10 AS_IF([test "x$MAKEINFO" = "x"], [
11   MAKEINFO='echo makeinfo missing; true'
12   AC_MSG_WARN([Info documentation will not be built.])
13 ])
14 AC_SUBST([MAKEINFO])
15
16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
17
18 AC_CONFIG_HEADERS([config.h])
19 AH_BOTTOM([
20 #include <helper/system.h>
21 #include <helper/types.h>
22 #include <helper/replacements.h>
23 ])
24
25 AC_LANG_C
26 AC_PROG_CC
27 AC_PROG_CC_C99
28 AM_PROG_CC_C_O
29 AC_PROG_RANLIB
30 PKG_PROG_PKG_CONFIG([0.23])
31
32 dnl disable checks for C++, Fortran and GNU Java Compiler
33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
36 AC_DISABLE_SHARED
37 AC_PROG_LIBTOOL
38 AC_SUBST([LIBTOOL_DEPS])
39
40 dnl configure checks required for Jim files (these are obsolete w/ C99)
41 AC_C_CONST
42 AC_TYPE_LONG_LONG_INT
43
44 AC_SEARCH_LIBS([ioperm], [ioperm])
45 AC_SEARCH_LIBS([dlopen], [dl])
46
47 AC_CHECK_HEADERS([sys/socket.h])
48 AC_CHECK_HEADERS([elf.h])
49 AC_CHECK_HEADERS([dirent.h])
50 AC_CHECK_HEADERS([fcntl.h])
51 AC_CHECK_HEADERS([malloc.h])
52 AC_CHECK_HEADERS([netdb.h])
53 AC_CHECK_HEADERS([poll.h])
54 AC_CHECK_HEADERS([pthread.h])
55 AC_CHECK_HEADERS([strings.h])
56 AC_CHECK_HEADERS([sys/ioctl.h])
57 AC_CHECK_HEADERS([sys/param.h])
58 AC_CHECK_HEADERS([sys/select.h])
59 AC_CHECK_HEADERS([sys/stat.h])
60 AC_CHECK_HEADERS([sys/sysctl.h])
61 AC_CHECK_HEADERS([sys/time.h])
62 AC_CHECK_HEADERS([sys/types.h])
63 AC_CHECK_HEADERS([unistd.h])
64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
65 #include <stdio.h>
66 #ifdef STDC_HEADERS
67 # include <stdlib.h>
68 # include <stddef.h>
69 #else
70 # ifdef HAVE_STDLIB_H
71 #  include <stdlib.h>
72 # endif
73 #endif
74 #ifdef HAVE_SYS_SOCKET_H
75 # include <sys/socket.h>
76 #endif
77 ])
78
79 AC_HEADER_ASSERT
80 AC_HEADER_STDBOOL
81 AC_HEADER_TIME
82
83 AC_C_BIGENDIAN
84
85 AC_CHECK_FUNCS([strndup])
86 AC_CHECK_FUNCS([strnlen])
87 AC_CHECK_FUNCS([gettimeofday])
88 AC_CHECK_FUNCS([usleep])
89 AC_CHECK_FUNCS([vasprintf])
90 AC_CHECK_FUNCS([realpath])
91
92 # guess-rev.sh only exists in the repository, not in the released archives
93 AC_MSG_CHECKING([whether to build a release])
94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
95   build_release=no
96 ], [
97   build_release=yes
98 ])
99 AC_MSG_RESULT([$build_release])
100
101 # Adapter drivers
102 # 1st column -- configure option
103 # 2nd column -- description
104 # 3rd column -- symbol used for both config.h and automake
105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
110
111 m4_define([USB1_ADAPTERS],
112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
113         [[stlink], [ST-Link JTAG Programmer], [HLADAPTER_STLINK]],
114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]]])
119
120 m4_define([USB_ADAPTERS],
121         [[[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
122         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
123         [[aice], [Andes JTAG Programmer], [AICE]]])
124
125 m4_define([USB0_ADAPTERS],
126         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
127         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
128         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
129
130 m4_define([HIDAPI_ADAPTERS],
131         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
132
133 m4_define([HIDAPI_USB1_ADAPTERS],
134         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
135
136 m4_define([LIBFTDI_ADAPTERS],
137         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
138         [[presto], [ASIX Presto Adapter], [PRESTO]],
139         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
140
141 m4_define([LIBJAYLINK_ADAPTERS],
142         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
143
144
145 AC_ARG_ENABLE([doxygen-html],
146   AS_HELP_STRING([--disable-doxygen-html],
147     [Disable building Doxygen manual as HTML.]),
148   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
149 AC_SUBST([doxygen_as_html])
150 AC_MSG_CHECKING([whether to build Doxygen as HTML])
151 AC_MSG_RESULT([$doxygen_as_html])
152
153 AC_ARG_ENABLE([doxygen-pdf],
154   AS_HELP_STRING([--enable-doxygen-pdf],
155     [Enable building Doxygen manual as PDF.]),
156   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
157 AC_SUBST([doxygen_as_pdf])
158 AC_MSG_CHECKING([whether to build Doxygen as PDF])
159 AC_MSG_RESULT([$doxygen_as_pdf])
160
161 AC_ARG_ENABLE([gccwarnings],
162   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
163   [gcc_warnings=$enableval], [gcc_warnings=yes])
164
165 AC_ARG_ENABLE([wextra],
166   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
167   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
168
169 AC_ARG_ENABLE([werror],
170   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
171   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
172
173 # set default verbose options, overridden by following options
174 debug_jtag_io=no
175 debug_usb_io=no
176 debug_usb_comms=no
177
178 AC_ARG_ENABLE([verbose],
179   AS_HELP_STRING([--enable-verbose],
180       [Enable verbose JTAG I/O messages (for debugging).]),
181   [
182   debug_jtag_io=$enableval
183   debug_usb_io=$enableval
184   debug_usb_comms=$enableval
185   ], [])
186
187 AC_ARG_ENABLE([verbose_jtag_io],
188   AS_HELP_STRING([--enable-verbose-jtag-io],
189       [Enable verbose JTAG I/O messages (for debugging).]),
190   [debug_jtag_io=$enableval], [])
191
192 AC_ARG_ENABLE([verbose_usb_io],
193   AS_HELP_STRING([--enable-verbose-usb-io],
194       [Enable verbose USB I/O messages (for debugging)]),
195   [debug_usb_io=$enableval], [])
196
197 AC_ARG_ENABLE([verbose_usb_comms],
198   AS_HELP_STRING([--enable-verbose-usb-comms],
199       [Enable verbose USB communication messages (for debugging)]),
200   [debug_usb_comms=$enableval], [])
201
202 AC_MSG_CHECKING([whether to enable verbose JTAG I/O messages]);
203 AC_MSG_RESULT([$debug_jtag_io])
204 AS_IF([test "x$debug_jtag_io" = "xyes"], [
205   AC_DEFINE([_DEBUG_JTAG_IO_],[1], [Print verbose JTAG I/O messages])
206 ])
207
208 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
209 AC_MSG_RESULT([$debug_usb_io])
210 AS_IF([test "x$debug_usb_io" = "xyes"], [
211   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
212 ])
213
214 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
215 AC_MSG_RESULT([$debug_usb_comms])
216 AS_IF([test "x$debug_usb_comms" = "xyes"], [
217   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
218 ])
219
220 debug_malloc=no
221 AC_ARG_ENABLE([malloc_logging],
222   AS_HELP_STRING([--enable-malloc-logging],
223       [Include free space in logging messages (requires malloc.h).]),
224   [debug_malloc=$enableval], [])
225
226 AC_MSG_CHECKING([whether to enable malloc free space logging]);
227 AC_MSG_RESULT([$debug_malloc])
228 AS_IF([test "x$debug_malloc" = "xyes"], [
229   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
230 ])
231
232 AC_ARG_ENABLE([dummy],
233   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
234   [build_dummy=$enableval], [build_dummy=no])
235
236 m4_define([AC_ARG_ADAPTERS], [
237   m4_foreach([adapter], [$1],
238         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
239                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
240                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
241                 [], [ADAPTER_VAR([adapter])=$2])
242   ])
243 ])
244
245 AC_ARG_ADAPTERS([
246   USB1_ADAPTERS,
247   USB_ADAPTERS,
248   USB0_ADAPTERS,
249   HIDAPI_ADAPTERS,
250   HIDAPI_USB1_ADAPTERS,
251   LIBFTDI_ADAPTERS,
252   LIBJAYLINK_ADAPTERS
253   ],[auto])
254
255 AC_ARG_ENABLE([parport],
256   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
257   [build_parport=$enableval], [build_parport=no])
258
259 AC_ARG_ENABLE([parport_ppdev],
260   AS_HELP_STRING([--disable-parport-ppdev],
261       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
262     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
263
264 AC_ARG_ENABLE([parport_giveio],
265     AS_HELP_STRING([--enable-parport-giveio],
266       [Enable use of giveio for parport (for CygWin only)]),
267     [parport_use_giveio=$enableval], [parport_use_giveio=])
268
269 AC_ARG_ENABLE([jtag_vpi],
270   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
271   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
272
273 AC_ARG_ENABLE([amtjtagaccel],
274   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
275   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
276
277 AC_ARG_ENABLE([zy1000_master],
278   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
279   [build_zy1000_master=$enableval], [build_zy1000_master=no])
280
281 AC_ARG_ENABLE([zy1000],
282   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
283   [build_zy1000=$enableval], [build_zy1000=no])
284
285 AC_ARG_ENABLE([ioutil],
286   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
287   [build_ioutil=$enableval], [build_ioutil=no])
288
289 AS_CASE(["${host_cpu}"],
290   [arm*], [
291     AC_ARG_ENABLE([ep93xx],
292       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
293       [build_ep93xx=$enableval], [build_ep93xx=no])
294
295     AC_ARG_ENABLE([at91rm9200],
296       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
297       [build_at91rm9200=$enableval], [build_at91rm9200=no])
298
299     AC_ARG_ENABLE([bcm2835gpio],
300       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
301       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
302     AC_ARG_ENABLE([imx_gpio],
303       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
304       [build_imx_gpio=$enableval], [build_imx_gpio=no])
305   ],
306   [
307     build_ep93xx=no
308     build_at91rm9200=no
309     build_bcm2835gpio=no
310     build_imx_gpio=no
311 ])
312
313 AC_ARG_ENABLE([gw16012],
314   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
315   [build_gw16012=$enableval], [build_gw16012=no])
316
317 AC_ARG_ENABLE([oocd_trace],
318   AS_HELP_STRING([--enable-oocd_trace],
319   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
320   [build_oocd_trace=$enableval], [build_oocd_trace=no])
321
322 AC_ARG_ENABLE([buspirate],
323   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
324   [build_buspirate=$enableval], [build_buspirate=no])
325
326 AC_ARG_ENABLE([sysfsgpio],
327   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
328   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
329
330 AS_CASE([$host_os],
331   [linux*], [],
332   [
333     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
334       AC_MSG_ERROR([sysfsgpio is only available on linux])
335     ])
336 ])
337
338 AC_ARG_ENABLE([minidriver_dummy],
339   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
340   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
341
342 AC_ARG_ENABLE([internal-jimtcl],
343   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
344   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
345
346 AC_ARG_ENABLE([internal-libjaylink],
347   AS_HELP_STRING([--disable-internal-libjaylink],
348   [Disable building internal libjaylink]),
349   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
350
351 AC_ARG_ENABLE([target64],
352   AS_HELP_STRING([--disable-target64], [Disable 64-bit target address]),
353     [build_target64=$enableval], [build_target64=yes])
354
355 build_minidriver=no
356 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
357 AS_IF([test "x$build_zy1000" = "xyes"], [
358   AS_IF([test "x$build_minidriver" = "xyes"], [
359     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
360   ])
361   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
362       [Define to 1 if you have the <jtag_minidriver.h> header file.])
363   build_minidriver=yes
364 ])
365 AC_MSG_RESULT([$build_zy1000])
366
367 AC_ARG_ENABLE([remote-bitbang],
368   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
369   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
370
371 AC_MSG_CHECKING([whether to enable dummy minidriver])
372 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
373   AS_IF([test "x$build_minidriver" = "xyes"], [
374     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
375   ])
376   build_minidriver=yes
377   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
378   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
379       [Define to 1 if you have the <jtag_minidriver.h> header file.])
380 ])
381 AC_MSG_RESULT([$build_minidriver_dummy])
382
383 AC_MSG_CHECKING([whether standard drivers can be built])
384 AS_IF([test "x$build_minidriver" = "xyes"], [
385   AC_MSG_RESULT([no])
386   AC_MSG_WARN([Using the minidriver disables all other drivers.])
387   sleep 2
388 ], [
389   AC_MSG_RESULT([yes])
390 ])
391
392 AS_CASE(["${host_cpu}"],
393   [i?86|x86*], [],
394   [
395     AS_IF([test "x$parport_use_ppdev" = "xno"], [
396       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
397     ])
398     parport_use_ppdev=yes
399 ])
400
401 AS_CASE([$host],
402   [*-cygwin*], [
403     is_win32=yes
404     parport_use_ppdev=no
405
406     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
407       [is_mingw=yes],[is_mingw=no])
408     AS_IF([test "x$is_mingw" = "xyes"], [
409       AS_IF([test "x$parport_use_giveio" = "xno"], [
410         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
411       ])
412       parport_use_giveio=yes
413       is_cygwin=no
414     ], [
415       is_cygwin=yes
416       # sys/io.h needed under cygwin for parport access
417       AS_IF([test "x$build_parport" = "xyes"], [
418         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
419       ])
420     ])
421   ],
422   [*-mingw* | *-msys*], [
423     is_mingw=yes
424     is_win32=yes
425     parport_use_ppdev=no
426
427     AS_IF([test "x$parport_use_giveio" = "xno"], [
428       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
429     ])
430     parport_use_giveio=yes
431
432     AS_IF([test "x$build_buspirate" = "xyes"], [
433       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
434     ])
435
436     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
437   ],
438   [*darwin*], [
439     is_darwin=yes
440
441     AS_IF([test "x$parport_use_giveio" = "xyes"], [
442       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
443     ])
444     parport_use_giveio=no
445   ],
446   [
447     AS_IF([test "x$parport_use_giveio" = "xyes"], [
448       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
449     ])
450     parport_use_giveio=no
451 ])
452
453 AS_IF([test "x$is_cygwin" = "xyes"], [
454     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
455 ], [
456     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
457 ])
458
459 AS_IF([test "x$is_mingw" = "xyes"], [
460     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
461 ], [
462     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
463 ])
464
465 AS_IF([test "x$is_win32" = "xyes"], [
466     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
467 ], [
468     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
469 ])
470
471 AS_IF([test "x$is_darwin" = "xyes"], [
472     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
473 ], [
474     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
475 ])
476
477 AS_IF([test "x$build_parport" = "xyes"], [
478   build_bitbang=yes
479   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
480 ], [
481   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
482 ])
483
484 AS_IF([test "x$build_dummy" = "xyes"], [
485   build_bitbang=yes
486   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
487 ], [
488   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
489 ])
490
491 AS_IF([test "x$build_ep93xx" = "xyes"], [
492   build_bitbang=yes
493   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
494 ], [
495   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
496 ])
497
498 AS_IF([test "x$build_zy1000" = "xyes"], [
499   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
500 ], [
501   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
502 ])
503
504 AS_IF([test "x$build_zy1000_master" = "xyes"], [
505   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
506 ], [
507   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
508 ])
509
510 AS_IF([test "x$build_at91rm9200" = "xyes"], [
511   build_bitbang=yes
512   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
513 ], [
514   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
515 ])
516
517 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
518   build_bitbang=yes
519   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
520 ], [
521   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
522 ])
523
524 AS_IF([test "x$build_imx_gpio" = "xyes"], [
525   build_bitbang=yes
526   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
527 ], [
528   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
529 ])
530
531 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
532   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
533 ], [
534   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
535 ])
536
537 AS_IF([test "x$parport_use_giveio" = "xyes"], [
538   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
539 ], [
540   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
541 ])
542
543 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
544   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
545 ], [
546   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
547 ])
548
549 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
550   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
551 ], [
552   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
553 ])
554
555 AS_IF([test "x$build_gw16012" = "xyes"], [
556   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
557 ], [
558   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
559 ])
560
561 AS_IF([test "x$build_oocd_trace" = "xyes"], [
562   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
563 ], [
564   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
565 ])
566
567 AS_IF([test "x$build_buspirate" = "xyes"], [
568   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
569 ], [
570   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
571 ])
572
573 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
574   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
575     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
576   ], [
577     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
578   ])
579 ])
580
581 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
582   build_bitbang=yes
583   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
584 ], [
585   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
586 ])
587
588 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
589   build_bitbang=yes
590   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
591 ], [
592   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
593 ])
594
595 AS_IF([test "x$build_target64" = "xyes"], [
596   AC_DEFINE([BUILD_TARGET64], [1], [1 if you want 64-bit addresses.])
597 ], [
598   AC_DEFINE([BUILD_TARGET64], [0], [0 if you don't want 64-bit addresses.])
599 ])
600
601
602 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
603         use_libusb1=yes
604         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
605         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
606                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
607                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
608         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
609         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
610         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
611                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
612   ], [
613         use_libusb1=no
614         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
615 ])
616
617 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
618
619 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
620         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
621                 use_hidapi=yes
622                 break
623         ],[
624                 use_hidapi=no
625         ])
626 done
627
628 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
629         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
630 ])
631
632 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
633         [use_libjaylink=yes], [use_libjaylink=no])
634
635 m4_define([PROCESS_ADAPTERS], [
636   m4_foreach([adapter], [$1], [
637         AS_IF([test "x$build_zy1000" = "xyes"], [
638                 ADAPTER_VAR([adapter])=no
639         ])
640         AS_IF([test $2], [
641                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
642                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
643                 ], [
644                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
645                 ])
646         ], [
647                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
648                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
649                 ])
650                 ADAPTER_VAR([adapter])=no
651         ])
652         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
653   ])
654 ])
655
656 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
657 PROCESS_ADAPTERS([USB_ADAPTERS], ["x$use_libusb1" = "xyes" -o "x$use_libusb0" = "xyes"], [libusb-1.x or libusb-0.1])
658 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
659 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
660 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
661 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
662 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.1])
663
664 AS_IF([test "x$build_openjtag" = "xyes"], [
665   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
666     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
667     build_openjtag=no
668   ])
669 ])
670
671 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
672         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
673 ], [
674         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
675 ])
676 AM_CONDITIONAL([HLADAPTER], [test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"])
677
678 AS_IF([test "x$enable_jlink" != "xno"], [
679   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
680     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
681       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
682                 [--enable-subproject-build])
683     ], [
684       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
685     ])
686   ])
687 ])
688
689 # Presto needs the bitq module
690 AS_IF([test "x$enable_presto" != "xno"], [
691   build_bitq=yes
692 ])
693
694 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
695 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
696 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
697 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
698 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
699 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
700 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
701 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
702 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
703 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
704 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
705 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
706 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
707 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
708 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
709 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
710 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
711 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
712 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
713 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
714 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
715 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
716 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
717 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
718 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
719 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
720 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
721 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
722 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
723 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
724 AM_CONDITIONAL([TARGET64], [test "x$build_target64" = "xyes"])
725
726 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
727 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
728
729 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
730 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
731
732 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
733 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
734 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
735 #define _GNU_SOURCE
736 #include <unistd.h>
737 #include <stdlib.h>
738   ]], [[char **ep = environ;]]
739   )], [
740     AC_MSG_RESULT([yes])
741     has_environ=yes
742   ], [
743     AC_MSG_RESULT([no])
744
745     # Possibility #2: can environ be found in an available library?
746     AC_MSG_CHECKING([for extern environ])
747     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
748     extern char **environ;
749     ]], [[char **ep = environ;]]
750       )], [
751         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
752         has_environ=yes
753       ], [
754         has_environ=no
755       ])
756     AC_MSG_RESULT([${has_environ}])
757   ])
758
759 AS_IF([test "x${has_environ}" != "xyes" ], [
760   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
761 ])
762
763 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
764
765 # set default gcc warnings
766 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
767 AS_IF([test "x${gcc_wextra}" = "xyes"], [
768   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
769   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
770   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
771   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
772 ])
773 AS_IF([test "x${gcc_werror}" = "xyes"], [
774   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
775 ])
776
777 # overide default gcc cflags
778 AS_IF([test "x$gcc_warnings" = "xyes"], [
779   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
780 ])
781
782 AC_CONFIG_FILES([
783   Makefile
784 ])
785 AC_OUTPUT
786
787 echo
788 echo
789 echo OpenOCD configuration summary
790 echo --------------------------------------------------
791 m4_foreach([adapter], [USB1_ADAPTERS, USB_ADAPTERS, USB0_ADAPTERS,
792         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
793         LIBJAYLINK_ADAPTERS],
794         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
795         AS_CASE([$ADAPTER_VAR([adapter])],
796                 [auto], [
797                         echo "$s"yes '(auto)'
798                 ],
799                 [yes], [
800                         echo "$s"yes
801                 ],
802                 [no], [
803                         echo "$s"no
804         ])
805 ])
806 echo
807
808 AS_IF([test "x$build_oocd_trace" = "xyes"], [
809   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
810   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
811   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
812   echo
813 ])
814
815 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
816   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
817   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
818   echo 'release. If you regularly use this platform, please report to the OpenOCD'
819   echo 'Mailing List.'
820   echo
821 ])
822
823 AS_IF([test "x$build_ioutil" = "xyes"], [
824   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
825   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
826   echo 'release. If you regularly depend on this functionality, please report to the'
827   echo 'OpenOCD Mailing List.'
828   echo
829 ])